如何使 TObjectDictionary.Values 作为属性可访问？

Question

我有一个像这样的对象：

  TMyObj = class
  private
    FObjList: TObjectDictionary <integer, TMyObject>;
  public
    constructor Create;
    destructor Destroy;
    // How to access Values correctly? Something similar to this not working code
    property Values: TValueCollection read FObjList.Values write FObjList.Values;
  end;

  var MyObj: TMyObj;

要访问 FObjList 的值，我想写：

  for tmpObject in MyObj.Values do
...

我需要如何声明属性“Values”，以便 MyObj.Values 的行为与访问 MyObj.FObjList.Values 完全相同？

Answer 1

  /// Interface

  TMyDictionary = TObjectDictionary <integer, TMyObject>;
  TMyValueCollection = TDictionary<integer,TMyObject>.TValueCollection;

  TMyObj = class
  private
    FObjList: TMyDictionary;
    function GetValues: TMyValueCollection;
  public
    constructor Create;
    destructor Destroy; override;
    property Values: TMyValueCollection read GetValues;
  end;


/// Implementation


constructor TMyObj.Create;
begin
  inherited;
  FObjList := TMyDictionary.Create;
end;

destructor TMyObj.Destroy;
begin
  FObjList.Free;
  inherited;
end;

function TMyObj.GetValues: TMyValueCollection;
begin
  Result := FObjList.Values;
end;

Answer 2

TValueCollection 是 TDictionary 的嵌套类，必须进行限定。并且您最好为 Values 指定一个 getter 方法。

type   
  TMyObjectDictionary = TObjectDictionary <integer, TMyObject>;

  TMyObj = class   
  private
    FObjList: TMyObjectDictionary;
    function GetValues: TMyObjectDictionary.TValueCollection;  
  public
    property Values: TMyObjectDictionary.TValueCollection read GetValues;   
  end;

function TMyObj.GetValues: TMyObjectDictionary.TValueCollection;
begin
  Result := FObjList.Values;
end;

编辑： 起来！太晚了……但略有不同。