如何使用 sed 将方括号内的所有空格替换为下划线？

Question

我发现为了将 [some name] 转换为 [some_name] 我需要使用以下表达式：

s/\(\[[^ ]*\) /\1_/

即为以包含任意数量的非空格字符的文字“[”开头的任何内容创建反向引用捕获空格，替换为非空格字符，后跟下划线。但我还不知道如何更改此表达式，以便它适用于大括号内的所有下划线，例如将 [几个单词] 转换为 [a_few_words]。

我感觉我已经很接近了，但我只是缺少一大块知识，这些知识将解锁使这个东西在（SQL Server 的）行中包含的第一组 [] 的约束内无限次工作的关键在本例中为 DDL）。

任何建议都感激不尽......

Answer 1

所需的技巧有两个部分：

1. 当到达右方括号时停止替换（但在线上重复执行）：

   s/\(\[[^] ]*\) /\1_/g
   

   它匹配一个左方括号，后跟零个或多个既不是空格也不是右方括号的字符。全局后缀意味着该模式应用于以左方括号开头，最后在该行上跟随一个空白或右方括号的所有序列。另请注意，此正则表达式不会更改“[single-word] and context”，而原始正则表达式会将其转换为“[single-word]_and context”，这不是练习的目的。

2. 让 sed 从这次开始的地方重复搜索。不幸的是，没有一个真正好的方法可以做到这一点。 Sed 总是在被替换的文本之后继续搜索；这是我们不希望出现的情况之一。有时，您只需重复替换操作就可以逃脱惩罚。在这种情况下，您必须在每次替换成功时重复它，并在不再有替换时停止。

sed 中两个不太为人所知的操作是“:label”和“t”命令。不过，它们出现在 Unix 第七版（大约 1978 年）中，因此它们并不是新功能。第一个只是标识脚本中的一个位置，可以使用“b”（此处不需要）或“t”跳转到该位置：

<前><代码>[2addr]t [标签]

如果自最近读取输入行或执行“t”函数以来进行了任何替换，则分支到带有标签的“:”函数。如果未指定标签，则分支到脚本末尾。

太棒了：我们需要：

 sed -e ':redo; s/\(\[[^] ]*\) /\1_/g; t redo' data.file

例外 - 它不能在这样的一行上全部工作（至少在 MacOS X 上不行）。不过，这确实有效：

sed -e ':redo
        s/\(\[[^] ]*\) /\1_/g
        t redo' data.file

或者，正如评论中所述，您可以编写三个单独的“-e”选项（适用于 MacOS X）：

 sed -e ':redo' -e 's/\(\[[^] ]*\) /\1_/g' -e 't redo' data.file

给定数据文件：

a line with [one blank] word inside square brackets.
a line with [two blank] or [three blank] words inside square brackets.
a line with [no-blank] word inside square brackets.
a line with [multiple words in a single bracket] inside square brackets.
a line with [multiple words in a single bracket] [several times on one line]

显示的 sed 脚本的输出是：

a line with [one_blank] word inside square brackets.
a line with [two_blank] or [three_blank] words inside square brackets.
a line with [no-blank] word inside square brackets.
a line with [multiple_words_in_a_single_bracket] inside square brackets.
a line with [multiple_words_in_a_single_bracket] [several_times_on_one_line]

最后，阅读问题中的细则，如果您只需要在每行的第一个方括号字段中完成此操作，那么我们需要确保在开始匹配的方括号之前没有左方括号。这个变体有效：（

sed -e ':redo' -e 's/^\([^]]*\[[^] ]*\) /\1_/' -e 't redo' data.file

“g”限定符消失了——在给定循环的其他变体中可能不需要它；它的存在可能会使过程稍微更有效，但很可能基本上不可能检测到这一点。该模式现在锚定到行的开头（插入符号），并包含零个或多个在第一个左方括号之前不是左方括号的字符。）

示例输出：

a line with [two_blank] or [three blank] words inside square brackets.
a line with [no-blank] word inside square brackets.
a line with [multiple_words_in_a_single_bracket] inside square brackets.
a line with [multiple_words_in_a_single_bracket] [several times on one line]

Answer 2

在像 perl 这样具有“可执行”替换的语言中，这更容易：

perl -wne 's/(\[.*?])/ do { my $x = $1; $x =~ y, ,_,; $x } /ge; print'

或者更清楚地分割它：

sub replace_with_underscores {
    my $s = shift;
    $s =~ y/ /_/;
    $s
}
s/(\[.*?])/ replace_with_underscores($1) /ge;

.*? 是非贪婪匹配（以避免将两个相邻的括号短语混淆在一起）并且替换的 e 标志会导致对其进行求值，因此您可以调用函数来完成内部工作。