用户输入 .bat 脚本时出现问题

Question

我编写了以下 .bat 脚本

@echo off
@rem set variables
set CURRENT_DIR=%cd%
set SCRIPT_DIR=%~dp0%
set Program Files=%Program Files:Program Files=Progra~1%

:input
set INPUT=
echo Following are the installation choices you have:
echo        1. Choice1
echo        2. Choice2
echo        3. Choice3

set /P INPUT=Please select any of the above choice (1to 3) : %=%
echo input is %INPUT%
if "%INPUT%"=="" goto input

if "%INPUT%"=="1" (
    echo Choice 1 selected
    goto QUITNOW
)

if "%INPUT%"=="2" (
echo Choice 2 selected
set /p INPUT_1=Please enter input 1: %=%
echo input_1 is  %INPUT_1%
goto QUITNOW
)

if "%INPUT%"=="3" (
echo Choice 3 selected
set /p input_3= Please enter input_3: %=%
echo %input_3%
)

:QUITNOW
cd %CURRENT_DIR%
@echo on

首先，当它要求我选择选项并且我输入 2 时，它将 INPUT 变量设置为 2 并进入第二个 if 块。在 if 块中，它再次要求输入（INPUT_1），我确实输入了输入单词，但看起来这次没有设置 INPUT_1 变量。有人知道我哪里做错了吗？使用我的输入跟踪脚本的输出

C:\Documents and Settings\Administrator\Desktop>scriptA.bat
Following are the installation choices you have:
        1. Choice1
        2. Choice2
        3. Choice3
Please select any of the above choice (1to 3) : 2
input is 2
Choice 2 selected
Please enter input 1: failingHere
input_1 is

C:\Documents and Settings\Administrator\Desktop>

因此，如果您观察到它没有打印“failingHere”输入。如果您需要有关此内容的更多信息，请帮助并告诉我。

Answer 1

您的问题在于：

if "%INPUT%"=="2" (
    echo Choice 2 selected
    set /p INPUT_1=Please enter input 1: %=%
    echo input_1 is  %INPUT_1%
    goto QUITNOW
)

在运行该整个块（对于环境变量）之前，任何都会被评估。这意味着 %INPUT_1% 在设置之前先进行评估。

您需要做的是将：

setlocal enableextensions enabledelayedexpansion

放在脚本的顶部（以及退出之前的endlocal）并使用延迟扩展符号：

if "%INPUT%"=="2" (
    echo Choice 2 selected
    set /p INPUT_1=Please enter input 1: %=%
    echo input_1 is  !INPUT_1!
    goto QUITNOW
)

您可以使用以下脚本查看此操作：

@setlocal enableextensions enabledelayedexpansion
@echo off
set xx=1
if %xx%==1 (
    set xx=2
    echo %xx%
    echo !xx!
)
endlocal

输出：

1
2

因为%xx% 在读取整个 if 语句 时计算，而 !xx! 在读取整个 if 语句 时计算行被执行。

Answer 2

您使用了 ms-dos/dos-batch 标签，但我不认为 set /p 在 MS-DOS 中已经可用。我以为它被添加到Windows命令提示符（cmd）中。
如果没有，如果我当时就知道的话，我的基于批处理的文本冒险就会容易得多。 :)

Answer 3

您使用的是 /p 而不是 /P。改变它就会起作用。

if "%INPUT%"=="2" (
echo Choice 2 selected
set /P INPUT_1=Please enter input 1: %=%
echo input_1 is  %INPUT_1%
goto QUITNOW
)