使用批处理文件检查进程是否返回0

Question

我想使用批处理文件启动一个进程，如果它返回非零，则执行其他操作。我需要正确的语法。

像这样的事情：

::x.bat

@set RetCode=My.exe
@if %retcode% is nonzero
   handleError.exe

作为奖励，您可以考虑回答以下问题:)

• 如何使用 if 编写复合语句？
• 如果应用程序 My.exe 由于缺少某些 DLL 而无法启动，我的 if 还能工作吗？如果没有，我如何检测 My.exe 启动失败？

Answer 1

ERRORLEVEL 将包含最后一个命令的返回代码。遗憾的是，您只能检查 >= 。

请特别注意 MSDN 文档中 If 语句的这一行：

错误级别数字

指定一个真实的
仅当前一个程序的条件
由 Cmd.exe 运行返回退出代码
等于或大于数字。

因此，要检查 0，您需要跳出框框思考：

IF ERRORLEVEL 1 GOTO errorHandling
REM no error here, errolevel == 0
:errorHandling

或者如果您想首先编写错误处理代码：

IF NOT ERRORLEVEL 1 GOTO no_error
REM errorhandling, errorlevel >= 1
:no_error

有关 BAT 编程的更多信息：http://www.ericphelps.com/batch/
或者更具体的 Windows cmd： MSDN 使用批处理文件

Answer 2

如何编写复合语句
如果？

您可以使用括号在 if 块中编写复合语句。第一个括号必须与 if 位于同一行，第二个括号单独位于一行。

if %ERRORLEVEL% == 0 (
    echo ErrorLevel is zero
    echo A second statement
) else if %ERRORLEVEL% == 1 (
    echo ErrorLevel is one
    echo A second statement
) else (
   echo ErrorLevel is > 1
   echo A second statement
)

Answer 3

这并不完全是问题的答案，但每次我想了解当进程返回非零代码时如何让我的批处理文件退出并显示错误代码时，我都会在这里结束。

所以这是这个问题的答案：

if %ERRORLEVEL% NEQ 0 exit %ERRORLEVEL%

Answer 4

我正在做的项目，我们做了类似的事情。我们使用 errorlevel 关键字，因此它看起来像：

call myExe.exe
if errorlevel 1 (
  goto build_fail
)

这似乎对我们有用。请注意，您可以在括号中输入多个命令，例如 echo 或其他命令。另请注意，build_fail 定义为：

:build_fail
echo ********** BUILD FAILURE **********
exit /b 1

Answer 5

要检查进程/命令是否返回 0，请使用运算符 && == 0 或 not == 0 ||：

只需将运算符添加到您的脚本中：

execute_command && (

       echo\Return 0, with no execution error
) || (
        echo\Return non 0, something went wrong
     )

---

command && echo\Return 0 || echo\Return non 0

• 有关运算符的详细信息 行为请参阅：条件执行 || && ...

Answer 6

您可以使用下面的命令来检查它是否返回 0 或 1 ：

在下面的示例中，我正在检查一个特定文件中的字符串，如果文件中不存在该特定单词“Error”（如果存在），则该字符串将为您提供 1然后 0

find /i "| ERROR1 |" C:\myfile.txt
echo %errorlevel%

if %errorlevel% equ 1 goto notfound
goto found
:notfound
exit 1
:found
echo we found the text.