如何在TEdit控件中设置文本对齐方式

Question

我正在使用 Turbo C++ 资源管理器版（免费版）。有人知道如何设置 TEdit 控件的 textAlignment 吗？

Answer 1

您可能会发现这个问题的解决方案很有趣：

http://bcbjournal.com/bcbcaq/ ?loc=edits&caq=28

它通过为控件启用 ES_RIGHT Windows 样式使编辑框右对齐，但它是在创建组件时执行此操作的。由于历史原因，标准 Windows 编辑控件在创建后不支持更改对齐方式（官方是这样），如 这篇关于旧事新事的帖子。然而，正如您从检查各种声明和评论中可以看出的那样，这种情况已经发生了变化，尽管仍然没有记录，但应该是可能的。

因此，如果您想在不创建自己的组件的情况下执行此操作，可以使用 Windows API 函数 SetWindowLong 如下所示：

DWORD alignment = ES_RIGHT;
DWORD oldStyle = GetWindowLong(Edit1->Handle, GWL_STYLE);
DWORD newStyle = (oldStyle & ~(ES_LEFT | ES_CENTER | ES_RIGHT)) | alignment;
SetWindowLong(Edit1->Handle, GWL_STYLE, newStyle);

请注意，您可能需要致电 SetWindowPos 以使更改生效，如前面链接的帖子中的评论所述文本。

Answer 2

在 Delphi 上，我通过重载 TEdit 类型来做到这一点，以这种方式：

在接口部分，在任何 TForm 声明之前，我放置：

type
    TEdit=class(StdCtrls.TEdit)
    private
      FAlignment:TAlignment;
      procedure SetAlignment(Value:TAlignment);
    protected
      procedure CreateParams(var Params:TCreateParams);override;
    public
      constructor Create(AOwner:TComponent);override;
    published
      property Alignment:TAlignment read FAlignment write SetAlignment default taLeftJustify;
    end;

在实现部分，我放置这样的实现：

procedure TEdit.SetAlignment(Value:TAlignment);
begin
     if FAlignment<>Value
     then begin
               FAlignment:=Value;
               RecreateWnd;
          end;
end;

procedure TEdit.CreateParams(var Params:TCreateParams);
const
     Alignments:array[TAlignment] of Cardinal=(ES_LEFT,ES_RIGHT,ES_CENTER);
begin
     inherited CreateParams(Params)
     Params.Style:=Params.Style or Alignments[FAlignment];
end;

constructor TEdit.Create(AOwner:TComponent);
begin
     inherited Create(AOwner);
     FAlignment:=taLeftJustify;
end;

然后在表单 OnCreate 事件上放这样的话：

MyEditBox.Alignment:=taLeftJustify;
MyEditBox.Alignment:=taCenter;
MyEditBox.Alignment:=taRightJustify;

就是这样。

Pelase 注意到它可以改进很多，这只是将其添加到 TEdit 的概念验证，它不是关于创建一个新类（使用其他名称），也不是关于创建一个新组件。

希望这对某人有用。

PD：对于 TStringGrid 也可以实现相同的想法，只需在 stackoverflow.com 上搜索 CellsAlignment 或阅读帖子 Delphi：如何使 TStringGrid 中的单元格文本居中对齐？

Answer 3

要设置对齐属性 - 显示左对齐、居中对齐或右对齐的文本，您可以设置 Alignment 属性，例如，对于名为 Edit1 的编辑控件（它是表单对象的指针成员），将对齐方式设置为右对齐，您可以使用：

Edit1->Alignment = taRightJustify;

其他对齐属性是 taLeftJustify 和 taCenter。

这仅影响控件上字符的位置，而不会影响从右到左或从左到右对齐的情况。这可以通过设置 BiDiMode 属性 - bdLeftToRight、bdRightToLeft 进行调整（这些在从左到右和从右到左的语言中更重要）

或者我是否在问题中遗漏了一些明显的东西？

Answer 4

我还使得能够全部位于另一个单独的单元中，所以这里是：

unit AlignedTEdit;

interface

uses Windows,Classes,Controls,StdCtrls;

type
    TEdit=class(StdCtrls.TEdit)
    private
      FAlignment:TAlignment;
      procedure SetAlignment(Value:TAlignment);
    protected
      procedure CreateParams(var Params:TCreateParams);override;
    public
      constructor Create(AOwner:TComponent);override;
    published
      property Alignment:TAlignment read FAlignment write SetAlignment default taLeftJustify;
    end;

implementation

procedure TEdit.SetAlignment(Value:TAlignment);
begin
     if FAlignment<>Value
     then begin
               FAlignment:=Value;
               RecreateWnd;
          end;
end;

procedure TEdit.CreateParams(var Params:TCreateParams);
const
     Alignments:array[TAlignment] of Cardinal=(ES_LEFT,ES_RIGHT,ES_CENTER);
begin
     inherited CreateParams(Params);
     Params.Style:=Params.Style or Alignments[FAlignment];
end;

constructor TEdit.Create(AOwner:TComponent);
begin
     inherited Create(AOwner);
     FAlignment:=taLeftJustify;
end;

end.

这是一个完整的单元，将其保存到名为 AlignedTEdit.pas 的文件中。

然后，在任何表单上，您都有一个 TEdit 添加 ,AlignedTEdit 在界面使用子句的末尾。

PD：对于 TStringGrid 也可以实现相同的想法，只需在 stackoverflow.com 上搜索 TStringGrid.SetCellsAlignment 或阅读帖子 Delphi：如何使 TStringGrid 中的单元格文本居中对齐？