将向量方程转换为 Mathematica 中的方程列表

Question

由于 DSolve 语法，微分方程组必须以方程列表的形式给出，而不是以向量方程的形式给出（与 Solve 不同，Solve 接受两者）。 所以我的简单问题是如何转换矢量方程，例如：

{f'[t],g'[t]}=={{a,b},{c,d}}.{f[t],g[t]}

到方程列表：

{f'[t]==a*f[t]+b*g[t],g'[t]==c*f[t]+d*g[t]}

我想我曾经知道答案，但我现在找不到它，我认为它也可以使其他人受益。

Answer 1

尝试使用 Thread：

Thread[{f'[t], g'[t]} == {{a, b}, {c, d}}.{f[t], g[t]}]
(* {f'[t] == a f[t] + b g[t], g'[t] == c f[t] + d g[t] *)

它采用相等运算符 == 并将其应用于具有相同 Head 的列表中的每个项目。

Answer 2

这个问题的标准答案是 Brett 提出的，
即，使用Thread。
但是，我发现在 DSolve、NDSolve 等中使用...命令 LogicalExpand 更好。

eqn = {f'[t], g'[t]} == {{a, b}, {c, d}}.{f[t], g[t]};

LogicalExpand[eqn]

(* f'[t] == a f[t] + b g[t] && g'[t] == c f[t] + d g[t] *)

它不会将向量方程转换为列表，但它更有用，因为它会自动展平矩阵/张量方程以及向量方程的组合。
例如，如果你想在上面的微分方程中添加初始条件，你可以使用

init = {f[0], g[0]} == {f0, g0};

LogicalExpand[eqn && init]

(* f[0] == f0 && g[0] == g0 && 
  f'[t] == a f[t] + b g[t] && g'[t] == c f[t] + d g[t] *)

矩阵方程的一个例子是

mEqn = Array[a, {2, 2}] == Partition[Range[4], 2];

Thread这里很尴尬，你需要多次应用它压平结果。使用 LogicalExpand 很简单

LogicalExpand[mEqn]

(* a[1, 1] == 1 && a[1, 2] == 2 && a[2, 1] == 3 && a[2, 2] == 4 *)