强制备份问题

Question

为了安全起见，备份perforce服务器目录下的所有文件是否足够？

Answer 1

简短回答：否
长答案：您需要了解的有关 Perforce 数据备份和恢复的所有信息，请参阅 手动。简而言之，对于不耐烦的人：

1. p4 verify //...
   （验证服务器的完整性）
2. p4 管理检查点
   （做一个检查点；确保这一步成功）
3. 备份检查点文件和旧的日志文件
   （如果您使用日志文件运行 Perforce，您应该这样做）
4. 备份您的版本化文件
   （这是实际数据，不要与 Perforce 服务器目录中的 db.* 文件混淆。）

但请务必阅读手册，尤其是有关各种恢复方案的内容。记住：
备份通常工作正常，只是恢复失败。

Answer 2

除了 p4 手动答案中 jhwist 的正确答案（永久链接）我想添加这是我在使用 Perforce 几年的过程中学到的一些东西。

...

根据存储库的大小，对 p4 数据库执行验证可能需要几个小时，在此期间将被锁定，并且没有人能够执行任何查询。锁定 P4 数据库可能会对用户产生多种流程影响，例如：如果有人在这段时间内使用或尝试使用 P4，P4SCC 插件（即用于 Visual Studio 集成）将会旋转，用户最终会必须强制退出才能重新获得控制权。

解决方案

1. 在不同端口上生成第二个 P4D 实例 (p4d_2)
2. 挂起/终止主实例 (p4d_1)。
3. 使用 p4d_2 执行 p4 verify //... 和检查点。
4. 备份存储阵列上的物理版本文件。
5. 杀死 p4d_2。
6. 重新启动 p4d_1。

另外：由于这很可能是在晚上或周末运行的自动化过程，因此您必须需要彻底阅读检查点日志文件以确保其成功 否则，当您需要执行恢复时，您将陷入困境（请阅读下一点）。备份不应该是一个一劳永逸的过程。

有关 Perforce 备份的更多信息，请参阅 Perforce 白皮书：Perforce 的高可用性和灾难恢复解决方案。

哈特哈，

Answer 3

FWIW 我在自己的开发工作站上使用了额外的备份策略。我有一个 perl 脚本，每天晚上运行，并查找我从给定的工作空间列表中从 Perforce 签出的所有文件。然后，该文件列表将作为我正常工作站备份过程的一部分进行备份。查找已检出文件的 Perl 脚本对我来说看起来相当棘手。它不是我写的，对 Perl 也不是特别熟悉。

如果有人感兴趣，我可以在这里发布脚本以及我如何调用它。

请注意，该脚本是在 Perforce 推出“搁置”功能之前开发的。我现在可能会更好地拥有一个每天晚上“搁置”我的工作的脚本（除了我当前的备份策略之外或代替它）。

这是脚本：

# This script copies any files that are opened for any action (other than
# delete) in the specified client workspace to another specified directory.
# The directory structure of the workspace is duplicated in the target
# directory.  Furthermore, a file is not copied if it already exists in the
# target directory unless the file in the workspace is newer than the one
# in the target directory.

# Note: This script looks at *all* pending changelists in the specified
# workspace.
# Note: This script uses the client specification Root to get the local
# pathname of the files.  So if you are using a substituted drive for the
# client root, it must be properly substituted before running this script.

# Argument 1: Client workspace name
# Argument 2: Target directory (full path)

use File::Path;
# use File::Copy;
use File::Basename;
use Win32;

if ($#ARGV != 1) {
    die("usage: $0 client_name target_directory\n");
}

my $client = shift(@ARGV);
my $target_dir = shift(@ARGV);
my @opened_files = ();
my $client_root = "";
my $files_copied = 0;

# I need to know the root directory of the client, so that I can derive the
# local pathname of the file.  Strange that "p4 -ztag opened" doesn't give
# me the local pathname; I would have expected it to.

open(CLIENT_SPEC, "p4 -c $client client -o|")
        || die("Cannot retrieve client specification: $!");
while (<CLIENT_SPEC>) {
    my ($tag, $value) = split(/\s/, $_, 2);
    if ($tag eq "Root:") {
        $value = chop_line($value);
        $client_root = $value;
    }
}
close(CLIENT_SPEC);
if ($client_root eq "") {
    die("Unable to determine root of client $client\n");
} elsif (substr($client_root, -1) ne "\\") {
    $client_root = $client_root . "\\";
} 

# Use the -ztag option so that we can get the client file path as well as
# the depot path.

open(OPENED_FILES, "p4 -c $client -ztag opened|")
        || die("Cannot get list of opened files: $!");
while (<OPENED_FILES>) {
    # What we do is to get the client path and append it onto the
    # @opened_files array.  Then when we get the action, if it is a delete,
    # we pop the last entry back off the array.  This assumes that the tags
    # come out with clientFile before action.

    $_ = chop_line($_);
    my ($prefix, $tag, $value) = split(/\s/, $_, 3);
    if ($tag eq "clientFile") {
        push(@opened_files, $value);
    }
    if ( ($tag eq "action") && ($value eq "delete") ) {
        pop(@opened_files);
    }
}
close(OPENED_FILES);

# Okay, now we have the list of opened files.  Process each file to
# copy it to the destination.

foreach $client_path (@opened_files) {

    # Trim off the client name and replace it with the client root
    # directory.  Also replace forward slashes with backslashes.

    $client_path = substr($client_path, length($client) + 3);
    $client_path =~ s/\//\\/g;
    my $local_path = $client_root . $client_path;

    # Okay, now $client_path is the partial pathname starting at the
    # client's root.  That's the path we also want to use starting at the
    # target path for the destination.

    my $dest_path = $target_dir . "\\" . $client_path;
    my $copy_it = 0;

    if (-e $dest_path) {
        # Target exists.  Is the local path newer?
        my @target_stat = stat($dest_path);
        my @local_stat = stat($local_path);
        
        if ($local_stat[9] > $target_stat[9]) {
            $copy_it = 1;
        }
    } else {
        # Target does not exist, definitely copy it.  But we may have to
        # create some directories.  Use File::Path to do that.

        my ($basename, $dest_dir) = fileparse($dest_path);
        if (! (-e $dest_dir)) {
            mkpath($dest_dir) || die("Cannot create directory $dest_dir\n");
        }
        $copy_it = 1;
    }

    if ($copy_it) {
        Win32::CopyFile($local_path, $dest_path, 1)
                || warn("Could not copy file $local_path: $!\n");
        $files_copied++;
    }
}
print("$files_copied files copied.\n");

exit(0);

################ Subroutines #########################################

# chop_line removes any trailing carriage-returns or newlines from its
# argument and returns the possibly-modified string.

sub chop_line {
    my $string = shift;

    $string =~ s/[\r\n]*\z//;
    return $string;
}

运行：

REM Make sure that we are pointing to the current Perforce server
P4 set -s P4PORT=MyPerforceServer:ThePortThatPerforceIsOn
p4 set p4client=MyPerforceWorkspace

REM Copy checked out files to a local directory that will be backed up
.\p4backup.pl MyPerforceWorkspace c:\PerforceBackups\MyPerforceWorkspace_backup