如何将 WriteLn 与枚举类型一起使用？

Question

我正在尝试为一周中的几天创建自定义数据类型，但我无法让它编写它。编译器错误是这样说的：

[错误]hours.dpr(28)：Write/Writeln 语句中的类型非法

program hours;

{$APPTYPE CONSOLE}

uses
  SysUtils;

type
  TypeDay = (Sun,Mon,Tue,Wed,Thu,Fri,Sat);

var day: TypeDay;

begin
     for day := Sun to Sat do
     begin
         writeln(day);
     end;
end.

它位于 Windows 上的 Delphi 7 中。

Answer 1

您不需要为此编写汇编程序； TypInfo 包括执行此操作所需的所有内容（获取与枚举值关联的字符串）。

此代码：

program hours;

{$APPTYPE CONSOLE}

uses
  SysUtils,
  TypInfo;

type
  TypeDay = (Sun,Mon,Tue,Wed,Thu,Fri,Sat);

var
  day: TypeDay;
  Str:String;

begin
     for day := Sun to Sat do begin
        Str := GetEnumName(TypeInfo(TypeDay),ord(day));
         writeln(Str);
     end;
end.

这是输出：

问候。

Answer 2

Tom，Writeln 不支持 Enum 作为参数。您必须调用 Ord 函数才能获取序数表示。如果你想显示你的 TypeDay 的名称，你可以编写这样的代码。

program hours;

{$APPTYPE CONSOLE}

uses
  SysUtils;

type
  TypeDay     = (Sun,Mon,Tue,Wed,Thu,Fri,Sat);
const
  TypeDayStr  : Array[TypeDay] of string = ('Sun','Mon','Tue','Wed','Thu','Fri','Sat');

var day: TypeDay;

begin
     for day := Sun to Sat do
       writeln( Ord(day));

     for day := Sun to Sat do
       writeln( TypeDayStr[day]);

     Readln;
end.

Answer 3

您可以使用 RTTI 来编写枚举名称。

这是我前段时间编写的一个优化函数：

program hours;

{$APPTYPE CONSOLE}

uses
  SysUtils;

function GetEnumName(aTypeInfo: pointer; aIndex: integer): PShortString;
asm // get enumerate name from RTTI
    or edx,edx
    movzx ecx,byte ptr [eax+1] // +1=TTypeInfo.Name
    mov eax,[eax+ecx+1+9+1] //BaseType
    mov eax,[eax]
    movzx ecx,byte ptr [eax+1]
    lea eax,[eax+ecx+1+9+4+1] // eax=EnumType.BaseType^.EnumType.NameList
    jz @0
@1: movzx ecx,byte ptr [eax]
    dec edx
    lea eax,eax+ecx+1 // next short string
    jnz @1
@0:
end;

type
  TypeDay = (Sun,Mon,Tue,Wed,Thu,Fri,Sat);

var day: TypeDay;

begin
     for day := Sun to Sat do
     begin
         writeln(GetEnumName(TypeInfo(TypeDay),ord(day))^);
     end;
end.

但请注意，此版本不会检查 aIndex 是否在范围内。

Answer 4

枚举不是字符串，因此您需要将它们转换。
对于转换，您可以使用 Delphi TypInfo 单元中的 GetEnumName 函数作为 在 delphi.about.com 进行了解释。

——杰罗恩

Answer 5

有趣的是，我可以在 FPC (Lazarus) 中使用带有枚举类型的 readLn，但会抛出与上面在 Delphi、Oxygene、PascalABC.Net 中提到的相同的错误（非法类型）...

    type
        beverage = (coffee, tea, milk, water, coke, limejuice);
    
    var
        drink : beverage;
    
    begin
         writeLn('Which drink do you want? ');
         writeLn('Here are the choices: coffee, tea, milk, water, coke, limejuice ');
         readLn(drink);
         writeLn('So you would like to drink ', drink, '.');
         readLn
    end.