删除子项和错误 2025

Question

我想通过另一个类删除一个孩子（背景）。我似乎无法瞄准它！它总是返回 null 或错误 2025 之类的东西......呵呵。

我的类creationObjets中有背景：

package cem{
    import flash.display.Sprite;

    public class creationBackground extends Sprite{

        public function creationBackground() {
            switch(monterJeu._Difficulte){
                case 0:
                    backgroundFacile();
                    break;
                case 1:
                    backgroundMoyen();
                    break;
                case 2:
                    backgroundDifficile();
                    break;
            }
        }
        private function backgroundFacile():void{
            var backgroundStage:Sprite = new Sprite();
            backgroundStage.graphics.beginFill(0x8FCCA8);
            backgroundStage.graphics.moveTo(0,0);
            backgroundStage.graphics.lineTo(750,0);
            backgroundStage.graphics.lineTo(750,450);
            backgroundStage.graphics.lineTo(0,450);
            backgroundStage.graphics.lineTo(0,0);
            backgroundStage.graphics.endFill();

            this.addChild(backgroundStage);
        }
        private function backgroundMoyen():void{
            var backgroundStage:Sprite = new Sprite();
            backgroundStage.graphics.beginFill(0x8F3378);
            backgroundStage.graphics.moveTo(0,0);
            backgroundStage.graphics.lineTo(750,0);
            backgroundStage.graphics.lineTo(750,450);
            backgroundStage.graphics.lineTo(0,450);
            backgroundStage.graphics.lineTo(0,0);
            backgroundStage.graphics.endFill();

            this.addChild(backgroundStage);
        }
        private function backgroundDifficile():void{
            var backgroundStage:Sprite = new Sprite();
            backgroundStage.graphics.beginFill(0x233378);
            backgroundStage.graphics.moveTo(0,0);
            backgroundStage.graphics.lineTo(750,0);
            backgroundStage.graphics.lineTo(750,450);
            backgroundStage.graphics.lineTo(0,450);
            backgroundStage.graphics.lineTo(0,0);
            backgroundStage.graphics.endFill();

            this.addChild(backgroundStage);
        }
    }
}

public static var _creationBackground:creationBackground = new creationBackground();

下面，我添加它：

addChild(_creationBackground);

然后我想从另一个类actionObjets中删除它！我怎样才能了解我的背景？ 我尝试了

creationObjets._creationBackground.parent.removeChild(creationObjets._creationBackground);

removeChild(creationObjets._creationBackground);

我真的不知道如何访问它！

Answer 1

我不确定我是否正确理解您的问题，但是：

请记住，为了删除孩子，您需要访问孩子的舞台。如果您的 actionObjects 类是 Movieclip 或 sprite，它将有一个引用舞台的只读变量（该变量可能与您添加 _creationBackground 的舞台相同，也可能不同）。

例如：

stage.removeChild(_creationBackground);

如果 actionObjets 与您添加 _creationBackground 的位置具有相同的阶段，则应该可以正常工作。

如果actionObjets没有相同的stage或根本没有（也许它不是sprite或movieclip？），您可以传入添加了_creationBackground的stage。

IE：

package {

import flash.display.Stage;

public class actionObjets {

    private var myStage:Stage;

    public function actionObjets(s:Stage) {
        myStage = s;
    }
}

}

然后尝试：

 myStage.removeChild(_creationBackground);

这当然是假设您有权访问 actionObjets 内的 _creationBackground 剪辑。

不确定这是否解决了您的问题，
祝你好运。

Answer 2

以下任何一项都应该足够：

creationObjets.removeChild(creationObjet.getChildAt(0));

或

creationObjets.removeChild(creationObjet.getChildByName("creationBackground"));

或

creationObjets.removeChildAt(0);

当您使用removeChildAt() 或getChildAt() 时，您必须指定显示对象的（您想要获取或删除的）索引位置。索引位置是显示对象在显示对象容器的显示列表中的位置（我假设它是0）。

此外，当使用 getChildByName() 时，您必须指定要获取的显示对象的名称。请注意，您必须首先设置显示对象的 name 属性。

下面是一个基于 Flash 应用程序/电影的工作示例：

package
{
    import cem.CreationObjet;
    import cem.ActionObjet;
    import flash.display.MovieClip;

    public class Main extends MovieClip
    {
        public function Main():void
        {
            init();

        }// end function

        private function init():void
        {
            var creationObjet:CreationObjet = new CreationObjet();
            addChild(creationObjet);

            var actionObjet:ActionObjet = new ActionObjet(creationObjet);

        }// end function

    }// end class

}// end package

在文档类 Main 中，首先导入 CreationObjet 和 ActionObjet。接下来，声明、实例化 CreationObjet 的实例并将其添加到舞台中。最后声明并实例化 ActionObjet 的实例，并将 CreationObjet 的实例解析为其唯一参数。

package cem
{
    import cem.CreationBackground;
    import flash.display.Sprite;

    public class CreationObjet extends Sprite
    {
        private var _creationBackground:CreationBackground;

        public function CreationObjet():void
        {
            _creationBackground = new CreationBackground();
            addChild(_creationBackground);

        }// end function

    }// end class

}// end package

在CreationObjet 类中，CreationBackground 的实例被添加到CreationObjet 显示对象中。

package cem
{
    import cem.CreationObjet;

    public class ActionObjet
    {
        private var _creationObjet:CreationObjet;

        public function ActionObjet(p_creationObjet:CreationObjet):void
        {
            _creationObjet = p_creationObjet;

            _creationObjet.removeChild(_creationObjet.getChildAt(0));
            // or _creationObjet.removeChild(_creationObjet.getChildByName("creationBackground"));
            // or _creationObjet.removeChildAt(0);

        }// end function

    }// end class

}// end package

最后在 ActionObjet 类中，CreationBackground 显示对象从 CreationObjet 中删除。

我不得不对您的 Flash 应用程序/电影做出一系列假设，但这应该能让您大致了解如何实现我之前建议的内容。

我希望这有帮助:)