从文件名中删除特殊字符的脚本

Question

我有一个包含大量文件的文件夹。许多文件名都有“%”和/或“&”其中的人物。

e.g. Test&doc.pdf
e.g Test%doc.doc

有没有一种快速方法可以删除“%”和“&”使用 Windows 批处理文件、vbscript 或类似文件的字符？

我们将不胜感激所有帮助。

谢谢。

Answer 1

这是批量执行此操作的方法（如果您好奇的话）。最大的限制是，如果文件名的符号超过百分之一，则它将不起作用，因为 shell 会将其扩展为变量。我不知道如何立即解决这个问题。

它从脚本所在的任何目录开始，并递归地处理所有子目录。

@echo off

setlocal enabledelayedexpansion
for /f "usebackq delims=" %%N in (`dir /s /b`) do (
  set var=%%~nN
  set var=!var:^&= !
  set var=!var:%%= !

  if not "!var!"=="%%~nN" (
    if not exist "%%~dpN!var!%%~xN" (
      echo "%%N" --^> "!var!%%~xN"
      ren "%%N" "!var!%%~xN"
    ) else (
      echo File "!var!%%~xN" ^(from %%N^) already exists.
    )
  )
)

例如，打印输出如下：

C:\batch\schar>schar
"C:\batch\schar\Test%doc.doc" --> "Test doc.doc"
"C:\batch\schar\Test%doc.pdf" --> "Test doc.pdf"
File "Test doc.pdf" (from C:\batch\schar\Test&doc.pdf) already exists.
"C:\batch\schar\subdir\FILE%here" --> "FILE here"

Answer 2

@indiv

如果有人可以生成没有字符限制的批处理解决方案，我将会印象深刻。

好的，我会尝试的。

@echo off

setlocal DisableDelayedExpansion
for /f "usebackq delims=" %%N in (`dir /s /b`) do (
  set var=%%~nxN
  setlocal EnableDelayedExpansion
  set "org=!var!"
  set "var=!var:&= !"
  set "var=!var:%%= !"

  if not "!var!"=="!org!" (
    if not exist "%%~dpN!var!" (
      echo "!org!" --^> "!var!"
      ren "!org!" "!var!"
    ) else (
      echo File "!var!" ^(from !org!^) already exists.
    )
  )
  endlocal
)

诀窍是，切换延迟扩展，因为 for-loop-vars (%%N) 的扩展应该在没有延迟扩展的情况下完成，否则您会丢失感叹号，并遇到插入符号问题。
但要处理和修改字符串，您应该使用延迟扩展。

但为什么？答案是了解批处理解析器的各个阶段。

我试图在这里解释一下。
how-does-the-windows-命令解释器-cmd-exe-解析脚本

Answer 3

我很快就把它们放在一起，但没有测试它，但这个 VBScript 应该可以解决问题。告诉我您是否需要文件夹递归替换等奇特的东西。

Set objFSO = CreateObject("Scripting.FileSystemObject")

'Your folder here
objStartFolder = "X:\MYFOLDER"

Set objFolder = objFSO.GetFolder(objStartFolder)
Set regEx = New RegExp

'Your pattern here
regEx.Pattern = "[&%]" 

Set colFiles = objFolder.Files
For Each objFile in colFiles
    objFile.Rename(regEx.Replace(objFile.Name, "")
Next