如何从窗体单元外部访问 Delphi 控件？

Question

我试图从如下定义的过程中调用计时器的 Enabled 属性： procedure Slide(Form: TForm; Show: Boolean); 并且不使用固定的表单名称（例如： Form2.Timer...）

将表单的单位放入使用列表中后，此方法有效：Form2.Timer1.Enabled := True; 但以下内容不起作用： Form.Timer1.Enabled := True; （其中 Form 是作为参数传递给过程的表单。

如何访问我的表单上的计时器组件？

谢谢进步。

Answer 1

如果您要传递到函数中的每个表单都有一个名为“Timer1”的已发布字段，那么您可以使用 FindComponent 方法来获取对其的引用：

procedure Slide(Form: TForm; Show: Boolean);
var
  TimerObj: TComponent;
  Timer: TTimer;
begin
  TimerObj := Form.FindComponent('Timer1');
  Assert(Assigned(TimerObj), 'Form has no Timer1');
  Assert(TimerObj is TTimer, 'Form.Timer1 is not a TTimer');
  Timer := TTimer(TimerObj);
  // Continue using Form and Timer
end;

不过，这是一个相当弱的编程接口。如果您不小心忽略了在表单上放置计时器，或者您给了它错误的名称，或者您给了它不同的可见性，那么直到运行时（当断言失败）。即使表单确实满足所需的接口，也不能保证它是故意的。可能有很多表单发布了名为 Timer1 的 TTimer 字段，但它们并不都适合与此 Slide 函数一起使用。它们可能已经将计时器用于其他目的，因此对它们调用 Slide 会破坏程序的其他部分，而且可能会以难以调试的方式破坏。

如果您为计时器指定一个更具描述性的名称（例如 SlideTimer），那么界面会稍微强大一些。 Timer1 只是表示它是您在该表单上创建的第一个 TTimer，一旦您离开表单设计器，它就不再是一个有意义的名称。您不需要使用 IDE 的命名选择。

---

另一个更好的选择是让所有可滑动表单都有一个公共基类，并将计时器放入该基类中。然后，更改 Slide 中的参数类型以采用该表单类，而不仅仅是 TForm。

type
  TSlidableForm = class(TForm)
    Timer1: TTimer;
  end;

procedure Slide(Form: TSlidableForm; Show: Boolean);

您似乎担心必须在 Slide 单元中包含对 Form2 单元的引用，这通常是一个值得关注的问题。您不希望代码耦合得太紧密，因为此 Slide 函数应该能够在一个项目中使用不止一种表单。但如果太松，就会遇到我上面描述的问题。这个TSlidableForm类是一个折衷方案；您的 Slide 函数未直接绑定到 TForm2 或其单元。将 TForm2 更改为 TSlidableForm 的下降形式。

---

The_Fox 的第二个建议< /a> 是我第一个的变体，但还有另一个变体。您可以传递对组件本身的引用，而不是传递计时器组件的名称：

procedure Slide(Form: TForm; Timer: TTimer; Show: Boolean);

现在您不需要使用FindComponent来搜索要使用的计时器;您已经提供了对其的直接引用。组件的名称并不重要，因此不同的形式可以使用不同的名称。您可以这样称呼它：

Slide(Form2, Form2.Timer1, True);
Slide(AnotherForm, AnotherForm.SlideTimer, False);

---

一旦您走到这一步，您可能会超越原来的问题，并意识到计时器甚至不再需要属于表单。您可以专门为调用 Slide 创建它，或者计时器可以完全属于其他东西（例如数据模块）。但是，如果您打算仅为 Slide 调用创建计时器，那么您可以使用 David 的建议，在例程本身内创建计时器，而根本不需要调用者或表单处理它：

procedure Slide(Form: TForm; Show: Boolean);
var
  Timer: TTimer;
begin
  Timer := TTimer.Create(nil);
  try
    Timer.OnTimer := ...;
    Timer.Interval := 500;
    Timer.Enabled := True;

    // Put your normal Slide stuff here
  finally
    Timer.Free;
  end;
end;

Answer 2

您无法从过程中访问 Timer，因为您的参数是 TForm，而 TForm 没有 Timer1 成员。您必须像这样调整您的程序：

uses
  Unit2; //unit with your form

procedure Slide(Form: TForm2; Show: Boolean); //change TForm2 to the classname you use
begin
  Form.Timer1.Enabled := True;
end;

编辑：

如果您想传递任何表单，您可以尝试以下操作：

procedure Slide(Form: TForm; const aTimerName: string; Show: Boolean);
var
  lComponent: TComponent;
begin
  lComponent := Form.FindComponent(aTimerName);
  if Assigned(lComponent) and (lComponent is TTimer) then
    TTimer(lComponent).Enabled := True;
end;

从表单上的按钮像这样调用：

procedure TForm2.Button1Click(Sender: TObject);
begin
  Slide(Self, 'Timer1', False);
end;

或者让您的表单继承一个接口方法来打开定时器。但它有点复杂。

Answer 3

将单位添加到使用列表中。

...
implementation

uses Unit2;

{$R *.dfm}
...

Answer 4

使用当前单位使用列表中Form2的单位名称。

对于您的编辑：

通过使用 TForm 您无法访问 TTimer，因为 TForm 没有 没有 TTimer 那样的字段或属性。

因此您需要使用TForm1作为参数。

如果您有一个表单（例如 Form1），您要为其创建多个实例并向用户显示，则将过程语法更改为 procedure Slide(Form: TForm1; Show: Boolean);

但如果您如果有多种形式和不同的组成部分，就会变得很困难。您需要使用不同的参数重载过程。下面的代码显示了该方法。

Form1 单位

var
  Form1: TForm1;

implementation

{$R *.dfm}

uses Unit3;

procedure TForm1.Button1Click(Sender: TObject);
begin
Slide(Form1, True)
end;

Form2 单位

var
  Form2: TForm2;

implementation

{$R *.dfm}

uses Unit3;

procedure TForm2.Button1Click(Sender: TObject);
begin
Slide(Form2, True)
end;

您的程序所在的单位

unit Unit3;

interface

uses Forms, ExtCtrls, Unit1, Unit2;

procedure Slide(Form: TForm1; Show: Boolean) overload;
procedure Slide(Form: TForm2; Show: Boolean) overload;

implementation


procedure Slide(Form: TForm2; Show: Boolean);
begin
  Form.Timer1.Enabled := True;
end;


procedure Slide(Form: TForm1; Show: Boolean);
begin
  Form.Timer1.Enabled := True;
end;

end.

Answer 5

只是添加一些更多信息。

在 Delphi 项目中，代码被组织成单元。每个单元都是一个具有名称和 .pas 扩展名的文件。

单元具有以下形式：

unit Name;

interface
uses
  // The definition of these units can be used both in the 
  // interface as in the implementation section.
  unit1, unit2;  

// Public interface, visible to other units that use this unit.

implementation
uses
  // The definition of these units can be used only in the 
  // implementation section.
  unit3, unit4;

// Private implementation, not visible outside.

initialization
  // code to initialize the unit, run only once
finalization
  // code to cleanup the unit, run only once
end.

单元可以使用单元中定义的任何内容，只要在使用之前定义它即可。

有时，如果名称相同，这会导致混乱的情况：

unit1;
interface
type
  TTest = Integer;
// ...

unit2;
interface
type
  TTest = Boolean;
// ...

unit3;
interface
uses
  unit1, unit2;
var
  a: TTest;  // Which TTest?
// ...

您可以通过了解计算顺序或使用单位前缀来解决此问题：

unit3;
interface
uses
  unit1, unit2;
var
  a: unit1.TTest;  // TTest from unit1
  b: unit2.TTest;  // TTest from unit2
// ...

在您的情况下，您需要使用定义 Form2 的单位。

如果两种表单都需要计时器，您还可以使用数据模块（就像表单一样，您可以将不可见的组件拖到其中，但它们将不可见）。两种形式都可以使用数据模块。

编辑

您尝试使用：

procedure Slide(Form: TForm; Show: Boolean); 

并且TForm没有Timer1。

您可以执行以下操作：

procedure Slide(Form: TForm2; Show: Boolean); 

如果 TForm2 是包含计时器的表单。

Answer 6

最简单的方法是在表单上找到它：

procedure Slide(Form: TForm; Show: Boolean);
var
  Timer: TTimer;
begin
  Timer := Form.FindComponent('Timer1');
  if Assigned(Timer) then
    Timer.Enabled := True;
end;

为了安抚大卫;-)，这里有一个更“类型安全”的替代方案：

procedure Slide(Form: TForm; Show: Boolean);
var
  i:  Integer;
begin
  // Could use a TComponent and for..in instead. This works in
  // all Delphi versions, though.
  for i := 0 to Form.ComponentCount - 1 do
    if Form.Components[i] is TTimer then
      TTimer(Form.Components[i]).Enabled := True;
end;♦♠

Answer 7

实现此目的的一种简单（和 OOP）方法是使用接口。

声明一个 ISlideable 接口，它定义一个 SlideTimer 属性（带有 getter 和 setter 方法），然后编写 Slide 方法，如下所示

Slide(const Target: ISlideable; Show: Boolean);

并且应该传递的每个表单都表示它是 Slideable

MyFormN = class(TForm, ISlideable)
...