vbscript 检查是否安装了.net 2.0

Question

你能分享一个检查计算机上是否安装了.NET 2.0的vb脚本吗？

我在网上进行了搜索，大多数此类“检查 .net 是否已安装”应用程序只是查找特定的注册表项，从而忽略了安装可能已损坏的事实。

基本上我正在寻找尝试创建 .NET 对象的脚本（这应该是肯定可以创建的 - 例如 System.Object），如果失败 - .NET 要么未安装，要么安装已损坏（因此并不比没有 .NET 更好）。 NET 已安装）。

Answer 1

检测是否安装了特定版本的 .NET Framework 的官方方法是检查相应的注册表项是否存在。在这种情况下，您正在寻找这个密钥：

HKLM\SOFTWARE\Microsoft\.NETFramework\Policy\v2.0

如果 REG_SZ 值“50727”存在，则您知道已安装 Framework 2.0 版本。

那么，如何在 VBScript 中做到这一点呢？这里有一个小脚本可以做到这一点：

Option Explicit
Dim oShell
Dim value

''#If the key isn't there when we try to read it, an error will be generated
''# that we will later test for, so we want to automatically resume execution.
On Error Resume Next

''#Try reading the registry value
Set oShell = CreateObject("WScript.Shell")
value = oShell.RegRead("HKLM\SOFTWARE\Microsoft\.NETFramework\Policy\v2.0\50727")

''#Catch the error
If Err.Number = 0 Then
    ''#Error code 0 indicates success
    MsgBox("Version 2.0 of the .NET Framework is installed.")
Else
    ''#Any other error code indicates failure
    MsgBox("Version 2.0 of the .NET Framework is NOT installed.")
End If

如果您想将此检查集成到现有 VBScript 中，我建议您将其转换为返回布尔值 的函数值（而不是显示消息框）取决于是否安装了正确版本的 .NET Framework。然后您可以从脚本中调用此函数。 注意：如果您选择此路线，请确保在函数结束时关闭错误处理（或至少返回到更合适的样式）！您不希望使用On Error Resume Next，除非您稍后在代码中显式处理错误。

On Error Goto 0    ''#Turn "On Error Resume Next" back off!

---

编辑：如果您确信要通过尝试实例化通用框架对象来确定 .NET 安装的有效性，则该脚本非常相似。 （事实上​​，它甚至比访问注册表还要简单一点。）和之前一样，使用了CreateObject，但这次是实例化基类System.Object的对象。 ：

On Error Resume Next

Dim testObj
Set testObj = CreateObject("System.Object")

If Err.Number = 0 Then
    MsgBox("Success")
Else
    MsgBox("Failure")
End If

但是，这不会告诉您安装了哪个版本的.NET Framework。此测试将通过任何版本，包括 1.1、2.0、4.0、未来版本等。您的问题似乎说明了版本 2.0 的要求，如果是这种情况，您确实应该考虑使用第一个选项。

我的经验是，这种“损坏”的框架安装极其罕见，如果您像我相信的那样频繁地看到它们，那么您可能会考虑安装正确版本的框架，这是理所当然的事情。我不相信能够实例化 System.Object 类型的对象实际上是对框架安装有效性的“真实”测试，而不是检查注册表项或目录是否存在。

现在已经过测试，可以在未安装 .NET Framework 的干净 Windows XP 虚拟机上运行。它正确报告故障。在安装了 .NET Framework 的其他计算机上，它可以正确报告成功。

Answer 2

这也有效，并且是 MSDN 网站上测试 .net 安装的推荐方法的精确副本。

网站 - http://support.microsoft.com/kb/318785/en-us

''official MSDN verison 2.0
value = oShell.RegRead("HKEY_LOCAL_MACHINE\Software\Microsoft\NET Framework Setup\NDP\v2.0.50727\Version")  
''#Catch the error 
If Err.Number = 0 Then     
    ''#Error code 0 indicates success        
    MsgBox("Version 2.0 of the official .NET Framework is installed.") 
Else     
''#Any other error code indicates failure     
    MsgBox("Version 2.0 of the official .NET Framework is NOT installed.") 
End If 

Answer 3

了解 .NET FRAMEWORK 2 是否正确安装的最佳选择是我建议创建一个脚本来查找“2 THINGS”；

1. 检查 RegKey 是否仍然存在，如“Cody Gray”所示。

2. 我会编写一段代码来检查 NET FRAMEWORK 2（位于 Windows 目录中）是否小于 75 MB（通常约为 82 -87 MB），如果小于，则表明它已被卸载或损坏。

通过将这两个代码放在一起，您将能够知道 NET FRAMEWORK 2 是否正确安装在用户计算机上