fslex 中的 Lua 长字符串

Question

我在业余时间一直在研究 Lua fslex 词法分析器，使用 ocamllex 手册作为参考。

我在尝试正确标记长字符串时遇到了一些障碍。 “长字符串”由 '[' ('=')* '[' 和 ']' ('=')* ']' 标记分隔； = 符号的数量必须相同。

在第一个实现中，词法分析器似乎无法识别 [[ 模式，尽管有最长匹配规则，但仍生成两个 LBRACKET 标记，而 [=[以及正确识别的变化。此外，正则表达式无法确保使用正确的结束标记，在第一个 ']' ('=')* ']' 捕获处停止，无论实际的长字符串“级别如何” ”。此外，fslex 似乎不支持正则表达式中的“as”结构。

let lualongstring =    '[' ('=')* '[' ( escapeseq | [^ '\\' '[' ] )* ']' ('=')* ']'

(* ... *)
    | lualongstring    { (* ... *) }
    | '['              { LBRACKET }
    | ']'              { RBRACKET }
(* ... *)

我一直在尝试用词法分析器中的另一条规则来解决这个问题：

rule tokenize = parse
    (* ... *)
    | '[' ('=')* '['   { longstring (getLongStringLevel(lexeme lexbuf)) lexbuf }
    (* ... *)

and longstring level = parse 
    | ']' ('=')* ']'   { (* check level, do something *) }
    | _                { (* aggregate other chars *) }

    (* or *)

    | _    {
               let c = lexbuf.LexerChar(0);
               (* ... *)           
           }

但是我被困住了，原因有两个：首先，我认为我不能“推送”，可以这么说，一次将令牌推到下一个规则我读完了长字符串；其次，我不喜欢逐字符读取直到找到正确的结束标记的想法，这使得当前的设计毫无用处。

如何在 fslex 中标记 Lua 长字符串？感谢您的阅读。

Answer 1

如果我回答我自己的问题，我很抱歉，但我想贡献自己的解决方案以供将来参考。

我使用 LexBuffer<_>.BufferLocalStore 属性来保持词法分析器函数调用的状态，该属性只是一个可写的 IDictionary 实例。

注意：长括号用于长字符串和多行注释。这常常是 Lua 语法中被忽视的部分。

let beginlongbracket =    '[' ('=')* '['
let endlongbracket =      ']' ('=')* ']'

rule tokenize = parse
    | beginlongbracket 
    { longstring (longBracketLevel(lexeme lexbuf)) lexbuf }

(* ... *)

and longstring level = parse
    | endlongbracket 
    { if longBracketLevel(lexeme lexbuf) = level then 
          LUASTRING(endLongString(lexbuf)) 
      else 
          longstring level lexbuf 
    }

    | _ 
    { toLongString lexbuf (lexeme lexbuf); longstring level lexbuf }

    | eof 
    { failwith "Unexpected end of file in string." }

以下是我用来简化将数据存储到 BufferLocalStore 中的函数：

let longBracketLevel (str : string) =
    str.Count(fun c -> c = '=')

let createLongStringStorage (lexbuf : LexBuffer<_>) =
    let sb = new StringBuilder(1000)
    lexbuf.BufferLocalStore.["longstring"] <- box sb
    sb

let toLongString (lexbuf : LexBuffer<_>) (c : string) =
    let hasString, sb = lexbuf.BufferLocalStore.TryGetValue("longstring")
    let storage = if hasString then (sb :?> StringBuilder) else (createLongStringStorage lexbuf)
    storage.Append(c.[0]) |> ignore

let endLongString (lexbuf : LexBuffer<_>) : string = 
    let hasString, sb = lexbuf.BufferLocalStore.TryGetValue("longstring")
    let ret = if not hasString then "" else (sb :?> StringBuilder).ToString()
    lexbuf.BufferLocalStore.Remove("longstring") |> ignore
    ret

也许它的功能不是很强大，但它似乎可以完成工作。

• 使用 tokenize 规则直到找到长括号的开头
• 切换到长字符串规则并循环直到找到相同级别的结束长括号将
• 每个与相同级别的结束长括号不匹配的词素存储到 StringBuilder 中，它又被存储到 LexBuffer BufferLocalStore 中。
• 一旦长字符串结束，就清除 BufferLocalStore。

编辑：您可以在 http://ironlua.codeplex.com 找到该项目。词法分析和解析应该没问题。我打算使用 DLR。欢迎评论和建设性批评。