如何在列表中的所有文件名前面添加公共路径？

Question

如何自动在列表中的所有文件名前面添加公共路径前缀？例如，在 CMakeLists.txt 中有一个文件列表：

SET(SRC_FILES foo1.cpp foo2.cpp)

我想获得一个与此等效的列表：

${CMAKE_CURRENT_SOURCE_DIR}/foo1.cpp ${CMAKE_CURRENT_SOURCE_DIR}/foo2.cpp

我需要它在 PARENT_SCOPE 上下文中使用文件名，例如

SET(FILES_TO_TRANSLATE ${FILES_TO_TRANSLATE} ${SRC_FILES} PARENT_SCOPE)

，另一个目录中的 CMakeFiles.txt 仍然可以找到这些文件。

本质上，我期望这样的东西（伪代码）：

SET(FILES_TO_TRANSLATE PREPEND_ALL_NAMES(${CMAKE_CURRENT_SOURCE_DIR} ${SRC_FILES}) PARENT_SCOPE)

这是很容易做到的，还是我必须使用“foreach”循环来创建新的文件列表？

Answer 1

CMake 3.12 添加了列表转换器 - 这些转换器之一是 PREPEND。因此，可以内联使用以下内容在列表中添加所有条目：

list(TRANSFORM FILES_TO_TRANSLATE PREPEND ${CMAKE_CURRENT_SOURCE_DIR})

...其中 FILES_TO_TRANSLATE 是以下变量的名称名单。

更多信息可以在 CMake 文档中找到。

Answer 2

以下功能可能就是您想要的。

FUNCTION(PREPEND var prefix)
   SET(listVar "")
   FOREACH(f ${ARGN})
      LIST(APPEND listVar "${prefix}/${f}")
   ENDFOREACH(f)
   SET(${var} "${listVar}" PARENT_SCOPE)
ENDFUNCTION(PREPEND)

要使用它，

PREPEND(FILES_TO_TRANSLATE ${CMAKE_CURRENT_SOURCE_DIR} ${SRC_FILES})

Answer 3

string(REGEX REPLACE "([^;]+)" "ANYPREFIX/\\1.cpp" outputlist "${inputlist}")

将 ANYPREFIX 替换为任何前缀，将“.cpp”替换为您需要的任何后缀。

Answer 4

您需要使用 foreach 循环。但如果您在项目的多个部分中使用它，您可能需要创建一个函数或宏。

Answer 5

作为对 Ding-Yi Chen 答案的改进，如果您仍然需要像我一样支持 3.12 之前的 CMake，您可以使用以下代码：

function(list_transform_prepend var prefix)
    set(temp "")
    foreach(f ${${var}})
        list(APPEND temp "${prefix}${f}")
    endforeach()
    set(${var} "${temp}" PARENT_SCOPE)
endfunction()

此解决方案的优点是，该接口更接近于 CMake 3.12 list( TRANSFORM ...) 并且更改就地完成。

像这样使用

list_transform_prepend(FILES_TO_TRANSLATE "${CMAKE_CURRENT_SOURCE_DIR}/")

Answer 6

我假设您需要绝对文件名，因为您要在 ${CMAKE_CURRENT_SOURCE_DIR} 前面添加。如果您使用 FILE(GLOB )，所有文件都将具有绝对路径：

file(GLOB_RECURSE SOURCE_FILES src/*.cpp)

请参阅 在文档中注释 CMake 为什么不使用 GLOB 添加源文件。

Answer 7

OP 询问如何在列表中的所有项目前面加上字符串。依赖于 list(TRANSFORM FILES_TO_TRANSLATE PREPEND ${CMAKE_CURRENT_SOURCE_DIR}) 之类的答案错过了这里的要点，因为它们向列表添加新项目，而不是修改现有列表项目。

通过查看 CMake 文档，我发现以下内容正是我所需要的：

list(TRANSFORM <existing_cmake_var> PREPEND <token_to_prepend>)

修改现有变量。如果您想保持现有变量不变，但将新变量设置为新列表（其中现有列表项将全部以开头，您可以使用以下语法：

list(TRANSFORM <existing_cmake_var> PREPEND <token_to_prepend> OUTPUT_VARIABLE <output_var_name>

示例：在我的情况下，我想添加将令牌 CONFIG_ 添加到现有列表中的所有令牌，并设置一个新变量，而不是修改原始变量：

set(DOXYGEN_OPTION_PREFS LOGGING COMPUTE)
list(TRANSFORM DOXYGEN_OPTION_PREFS PREPEND CONFIG_ OUTPUT_VARIABLE doxygen_predefined_list)

现在，doxygen_predenfined_list 具有该值

CONFIG_LOGGING CONFIG_COMPUTE

（此选项是在 CMake 3.12 中添加的）
https://cmake.org/cmake/help/latest/command/list。 html