Common Lisp 中的 str_replace？

Question

Common Lisp 中是否有类似于 PHP 的 str_replace 的函数？

http://php.net/manual/en/function.str-replace。 php

Answer 1

有一个名为 cl-ppcre 的库：

(cl-ppcre:regex-replace-all "qwer" "something to qwer" "replace")
; "something to replace"

通过 quicklisp 安装它。

Answer 2

如果替换只有一个字符（这种情况很常见），您可以使用 Replace：

(substitute #\+ #\Space "a simple example") => "a+simple+example"

Answer 3

我认为标准中没有这样的功能。如果您不想使用正则表达式 (cl-ppcre)，您可以使用：

(defun string-replace (search replace string &optional count)
  (loop for start = (search search (or result string)
                            :start2 (if start (1+ start) 0))
        while (and start
                   (or (null count) (> count 0)))
        for result = (concatenate 'string
                                  (subseq (or result string) 0 start)
                                  replace
                                  (subseq (or result string)
                                          (+ start (length search))))
        do (when count (decf count))
        finally (return-from string-replace (or result string))))

编辑： Shin Aoyama 指出这不适用于替换，例如 "\" " 与 "str\"ing" 中的 "\\\""。由于我现在认为上述内容相当麻烦，所以我应该建议中给出的实现Common Lisp Cookbook，其中好多了：

(defun replace-all (string part replacement &key (test #'char=))
  "Returns a new string in which all the occurences of the part 
is replaced with replacement."
  (with-output-to-string (out)
    (loop with part-length = (length part)
          for old-pos = 0 then (+ pos part-length)
          for pos = (search part string
                            :start2 old-pos
                            :test test)
          do (write-string string out
                           :start old-pos
                           :end (or pos (length string)))
          when pos do (write-string replacement out)
          while pos)))

我特别喜欢使用 with-output-to-string，它通常比 concatenate 性能更好。