如何最好地以编程方式判断 TLabel 的标题是否被剪裁（即使用省略号绘制）？

Question

我有一个 TLabel，其中 EllipsisPosition 设置为 epEndEllipsis，我需要能够判断文本当前是否被剪切。除了自己计算显示文本所需的面积并将其与标签的实际尺寸进行比较之外，有没有人想出一种更简单/更优雅的方法来做到这一点？

实际上，以自动防故障的方式计算所需区域似乎也不像听起来那么简单……例如，TCanvas.GetTextHeight 不考虑换行符。

TCustomLabel.DoDrawText 在内部使用 DrawTextW 或 DrawThemeTextEx 以及 DT_CALCRECT 标志来确定是否应使用省略号与否。这里涉及到相当多的代码，所有这些代码都被声明为私有。简单地复制所有这些代码在我的书中并不完全符合“优雅”的条件...

有什么想法吗？

（我正在使用 Delphi 2010，以防有人提出特定于 Delphi 版本的解决方案）

更新 1： 我现在发现我可以简单地调用 TCustomLabel.DoDrawText( lRect, DT_CALCRECT)（仅声明为受保护），让标签执行所需的尺寸计算，而无需重复其代码。我只需确保临时将 EllipsisPosition 设置为 epNone 或完全使用临时标签实例。这实际上并没有那么糟糕，如果没有人能想到更简单的解决方案，我可能会选择它。

更新 2： 我现在已将我的解决方案添加为单独的答案。事实证明，它比我预期的要直接得多，所以可能没有更简单/更好的方法来做到这一点，但无论如何，我都会把这个问题再留一会儿，以防万一。

Answer 1

FWIW，这就是我想到的（这是自定义 TLabel 后代的方法）：

function TMyLabel.IsTextClipped: Boolean;
const
  EllipsisStr = '...';
var
  lEllipBup: TEllipsisPosition;
  lRect: TRect;
begin
  lRect := ClientRect;
  Dec(lRect.Right, Canvas.TextWidth(EllipsisStr));

  lEllipBup := EllipsisPosition;
  EllipsisPosition := epNone;
  try
    DoDrawText(lRect, DT_CALCRECT or IfThen(WordWrap, DT_WORDBREAK));
  finally
    EllipsisPosition := lEllipBup;
  end;
  Result := ((lRect.Right - lRect.Left) > ClientWidth)
         or ((lRect.Bottom - lRect.Top) > ClientHeight);
end;

因为它现在使用与 TCustomLabel.DoDrawText 完全相同的逻辑（尤其是人工填充和正确的 WordWrap 设置）它还可以正确处理多行和自动换行的输入文本。请注意，在这种情况下，“正确”意味着“当使用剪切标题绘制 TLabel 时，它始终返回 True，否则返回 False”。

虽然上面的代码满足了我最初的要求，但我可能不会以这种方式使用它 - 但这更多是由于 TLabel 本身的缺点：特别是对于多行文本，它通常不会这样做我本来希望它，例如，当没有足够的空间容纳多行时，第一行的最后一个单词总是会被截断，即使整行加上省略号已经安装。

Answer 2

作为起点，您可以使用

function DrawStringEllipsis(const DC: HDC; const ARect: TRect; const AStr: string): boolean;
var
  r: TRect;
  s: PChar;
begin
  r := ARect;
  GetMem(s, length(AStr)*sizeof(char) + 8);
  StrCopy(s, PChar(AStr));
  DrawText(DC, PChar(s), length(AStr), r, DT_LEFT or DT_END_ELLIPSIS or DT_MODIFYSTRING);
  result := not SameStr(AStr, s);
  FreeMem(s);
end;

示例用法：

procedure TForm1.FormClick(Sender: TObject);
begin
  Caption := 'Clipped ' + BoolToStr(DrawStringEllipsis(Canvas.Handle, Rect(10, 100, 50, 50), 'This is a text.'), true);
end;

使用此技术编写具有 WasClipped 属性的 TExtLabel 组件并不困难。事实上，TLabel 组件是 VCL 中最简单的组件之一——它只是绘制一个字符串。