用于统计 iPhone 上方法调用次数的工具

Question

Time Profiler 可以测量某些方法所花费的时间量。是否有类似的方法来测量方法被调用的次数？

Answer 1

DTrace 可以做到这一点，但仅限于 iPhone 模拟器（Snow Leopard 支持它，但 iOS 尚不支持）。我在 MacResearch 上有两篇关于这项技术的文章 这里和此处，我将介绍一些使用 DTrace 查找特定方法及其调用时间的案例研究。

例如，我创建了以下 DTrace 脚本来测量对带有 CP 前缀的类调用方法的次数，以及计算在这些方法中花费的时间的总和：

#pragma D option quiet
#pragma D option aggsortrev

dtrace:::BEGIN
{
    printf("Sampling Core Plot methods ... Hit Ctrl-C to end.\n");
    starttime = timestamp;      
}

objc$target:CP*::entry
{
    starttimeformethod[probemod,probefunc] = timestamp;
    methodhasenteredatleastonce[probemod,probefunc] = 1;
}

objc$target:CP*::return
/methodhasenteredatleastonce[probemod,probefunc] == 1/
{
    this->executiontime = (timestamp - starttimeformethod[probemod,probefunc]) / 1000;
    @overallexecutions[probemod,probefunc] = count();
    @overallexecutiontime[probemod,probefunc] = sum(this->executiontime);
    @averageexecutiontime[probemod,probefunc] = avg(this->executiontime);
}

dtrace:::END 
{
    milliseconds = (timestamp - starttime) / 1000000;
    normalize(@overallexecutiontime, 1000);
    printf("Ran for %u ms\n", milliseconds);
    printf("%30s %30s %20s %20s %20s\n", "Class", "Method", "Total CPU time (ms)",  "Executions", "Average CPU time (us)");
    printa("%30s %30s %20@u %20@u %20@u\n", @overallexecutiontime, @overallexecutions, @averageexecutiontime);
}

生成以下格式良好的输出：

        Class                         Method  Total CPU time (ms)           Executions Average CPU time (us)
      CPLayer                -drawInContext:                 6995                  352                19874
       CPPlot                -drawInContext:                 5312                   88                60374
CPScatterPlot      -renderAsVectorInContext:                 4332                   44                98455
CPXYPlotSpace        -viewPointForPlotPoint:                 3208                 4576                  701
       CPAxis               -layoutSublayers                 2050                   44                46595
CPXYPlotSpace -viewCoordinateForViewLength:linearPlotRange:plotCoordinateValue:                 1870                 9152
...

这会 从命令行运行 DTrace 脚本，您最好的选择可能是在 Instruments 中创建自定义仪器并在该仪器中填写适当的 D 代码。然后，您可以在模拟器中针对您的应用程序轻松运行它。

同样，这在设备上不起作用，但如果您只想统计某项被调用的次数，而不是它运行的持续时间，这可能可以完成工作。