Xquery根据条件对结果进行分组

Question

我有一个关于 xquery 分组的问题。据我了解，通常的情况是在 for 循环中的文档上使用 distinct-values ，但是因为我在对值进行分组之前需要满足一个条件，而且我不太确定如何这是可以做到的。

这是我的 xmldb 的一部分：

<element tag="0001,0000" name="Pos1>198</element>
<element tag="0001,0001" name="Pos2">123</name>
<element tag="0002,0001" name="Pos3">433</element>
<element tag="000b,0000" name="Pos3">16</element>
<element tag="0005,0000" name="Pos4>532</element>
<element tag="0005,0001" name="Pos5">342</name>
<element tag="0008,0001" name="Pos6">17</element>

要满足的条件是 x 坐标（数字或十六进制）必须为奇数值（例如，从上面的 xml 中，我只需要 tag="0001,..." 的结果, tag="000b,...", tag="0005,...")，然后计算每组中有多少个项目。

结果应该是这样的：

<group>
<element xcoord="0001">2</element>
<element xcoord="000b">1</element>
<element xcoord="0005">2</element>
</group>

到目前为止，我的 xquery 代码看起来像这样，我可以生成具有奇数 x 坐标的结果，但我不知道如何从这里继续进行分组。

import module namespace functx="http://www.functx.com" at "http://www.xqueryfunctions.com/xq/functx-1.0-nodoc-2007-01.xq"; 

for $x in collection('/db/mapdb/')//element
let $coord := number(functx:substring-before-last($x/@tag, ","))
where $coord mod 2 != 0
return $x

请给我建议。非常感谢。

Answer 1

此 XQuery：

for $x in 
  distinct-values(/*/*/substring-before(@tag,',')
                    [contains('13579bdf', 
                               substring(., string-length(.))
                              )
                     ]
                  )
 return
   <element xcoord="{$x}">
    {count(/*/*[$x eq substring-before(@tag,',')])}
   </element>

产生所需的正确结果：

<element xcoord="0001">2</element>
<element xcoord="000b">1</element>
<element xcoord="0005">2</element>

Answer 2

此 XQuery：

<group>{
    for $key in distinct-values(/root/element/tokenize(@tag,',')[1])
                   [contains('13579bdf',substring(.,string-length(.)))]
    return <element xcoord="{$key}">{
               count(/root/element[tokenize(@tag,',')[1] eq $key])
          }</element>
}</group>

使用此输入：

<root>
    <element tag="0001,0000" name="Pos1">198</element>
    <element tag="0001,0001" name="Pos2">123</element>
    <element tag="0002,0001" name="Pos3">433</element>
    <element tag="000b,0000" name="Pos3">16</element>
    <element tag="0005,0000" name="Pos4">532</element>
    <element tag="0005,0001" name="Pos5">342</element>
    <element tag="0008,0001" name="Pos6">17</element>
</root>

输出：

<group>
    <element xcoord="0001">2</element>
    <element xcoord="000b">1</element>
    <element xcoord="0005">2</element>
</group>

注意：除了 eq 和 ne 之外，xs:hexBinary 数据类型没有内置运算符。

Answer 3

你没有说你正在使用哪个处理器。我在 try.zorba-xquery.com 上测试了以下代码（它也应该适用于 Saxon 或其他支持 XQuery 1.1 和 XPath 2.0 的处理器）：

let $xmldb :=
  (
    <element tag="0001,0000" name="Pos1">198</element>,
    <element tag="0001,0001" name="Pos2">123</element>,
    <element tag="0002,0001" name="Pos3">433</element>,
    <element tag="000b,0000" name="Pos3">16</element>,
    <element tag="0005,0000" name="Pos4">532</element>,
    <element tag="0005,0001" name="Pos5">342</element>,
    <element tag="0008,0001" name="Pos6">17</element>
  )
for $x in $xmldb
let $coord := tokenize($x/@tag, ",")[1]
group by $coord
where contains('13579bdf',substring($coord,string-length($coord)))
return <element xcoord="{$coord}">{count($x)}</element>

希望有帮助吗？

Answer 4

如果您使用的是 XQuery 1.0 处理器，则分组依据的常用模式是：

let $values := ...
for $key in distinct-values(for $value in $values return my:key($value))
let $group := $values[my:key(.)=$key]
return ...

其中 my:key 是获取每个输入值的键的函数/表达式。

在您的情况下，您可以如下填写模式：

for $coord in distinct-values($xmldb/(tokenize(.,",")[1]))
let $x := $xmldb[tokenize(.,",")[1] = $coord]
return <element xcoord="{$coord}">{count($x)}</element>

此操作是否有效取决于您的实现。我写了一篇关于如何编写XQSharp 能够识别的分组。

编辑：我错过了所有 x 坐标必须为奇数的要求。这可以通过添加一个 where 子句来约束坐标的最后一个字符来解决：

for $coord in distinct-values($xmldb/(tokenize(.,",")[1]))
where contains('13579bdf',substring($coord,string-length($coord)))
let $x := $xmldb[tokenize(.,",")[1] = $coord]
return <element xcoord="{$coord}">{count($x)}</element>