DelphiWin32 - 生成特定类的对象

Question

我正在使用 Delphi 2009。我有一个包含多个项目的 TListBox。我想为每个选定的项目生成特定类的对象。因此，如果用户选择项目编号 2 并单击“创建”按钮，则会创建特定类的对象。我想实现它只是检查当前所选项目的索引值，然后使用 if-then-else。或者我应该使用类引用，即对于每次单击项目我设置类引用的类型，然后在按钮的 OnClick 事件中创建对象？我想避免所有这些控件，只根据项目字符串的值创建对象。有什么想法吗？多谢！

Answer 1

有几种选择。

简单索引

简单的解决方案是：

case ListBox1.ItemIndex of
  0 : temp := TApple.Create;
  1 : temp := TPineapple.Create;
  2 : temp := TGrape.Create;
else
  raise EFruitError.Create('Unknown fruit');
end;

很清楚，但是你必须在两个地方维护列表，这可能会导致错误。

类引用

假设所有水果都来自 TFruit，并具有虚拟构造函数。然后你可以这样做：

procedure TForm1.FormCreate(const Sender: TObject);
begin
  ListBox1.AddObject('Apple', TApple);
  ListBox1.AddObject('Pineapple', TPineapple);
  ListBox1.AddObject('Grape', TGrape);
end;

// Event handler:
procedure TForm1.CreateButtonClick(const Sender: TObject);
begin
  if ListBox1.ItemIndex>=0 then
    temp := TFruit(ListBox1.Items.Objects[ListBox1.ItemIndex]).Create;
end;

这有一个单点维护。这太棒了。

基于名称的参考
但是，如果您想根据列表中的名称创建对象，则可以创建某种工厂：

type
  TFruitClass = class of TFruit;
  TFruitFactory = class
  public
    class function CreateFruit(const AName: string): TFruit;
    class procedure RegisterFruit(const AName: string; const AFruitClass: TFruitClass);
  end;

工厂用于将类绑定到名称。每个类都使用名称进行注册。现在，您只需为工厂提供名称，工厂就会返回所需的类。

Answer 2

要添加 Gamecat 的答案，您可以使用“classes.pas”中的类实用函数。下面的示例使用 GetClass 函数（并假设要创建的对象源自 TControl）：

procedure TForm1.FormCreate(Sender: TObject);
begin
  ListBox1.Items.CommaText := 'TEdit,TButton,TPanel';
  RegisterClasses([TButton, TEdit, TPanel]);
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  pc: TPersistentClass;
  c: TControl;
begin
  if ListBox1.ItemIndex > -1 then begin
    pc := GetClass(ListBox1.Items[ListBox1.ItemIndex]);
    if Assigned(pc) then begin
      c := TControlClass(pc).Create(Self);
      c.Parent := Self;
    end;
  end;
end;