Haskell：单个函数中的多个 Case 语句

Question

我想在 Haskell 函数中包含多个 case 语句（请参阅下面的假设函数示例）。

然而，它不是合法的 Haskell。完成同样事情的更好方法是什么？此外，如果 case 语句不返回任何内容，而只是设置某个值，那么为什么在函数中使用多个 case 语句是不合法的？

（我会在第 5 行收到“输入‘case’时出现解析错误”）

tester x y =  
   case (x < 0) of  
       True -> "less than zero."  
       False -> "greater than or equal to zero."  
   case (y == "foo")  
       True -> "the name is foo."  
       False -> "the name is not foo." 

请注意，如果我的函数只是：

tester x y =  
   case (x < 0) of  
       True -> "less than zero."  
       False -> "greater than or equal to zero."

...那么它将编译。

Answer 1

一般来说，函数体必须是单个表达式（通常由较小的表达式）。例如，以下内容是不允许的：

f x y =
  "foo"
  "bar"

这相当于您的第一个示例 - 我们刚刚用一种表达式（字符串文字）替换了另一种表达式（您的 case 表达式）。

当然可以在 Haskell 函数中包含多个 case 表达式：

tester :: Int -> String -> (String, String)
tester x y = (a, b)
  where
    a = case (x < 0) of  
          True -> "less than zero."  
          False -> "greater than or equal to zero."  
    b = case (y == "foo") of
          True -> "the name is foo."  
          False -> "the name is not foo."

或者甚至：

tester :: Int -> String -> IO ()
tester x y = do
  putStrLn $ case (x < 0) of  
               True -> "less than zero."  
               False -> "greater than or equal to zero."  
  putStrLn $ case (y == "foo") of
               True -> "the name is foo."  
               False -> "the name is not foo."

这些之所以有效，是因为函数的主体是单个表达式（尽管两者都不是真正惯用的 Haskell）。

Answer 2

不过，在这种情况下我不会使用 case 语句，这个 IMO 看起来更好：

tester :: Int -> String -> String
tester x y | x < 0     = "less than zero. " ++ expr
           | otherwise = "greater than or equal to zero. " ++ expr
    where expr = if y == "foo" then "the name is foo." else "the name is not foo." 

Answer 3

一般来说，看起来你想要的是守卫。但是，正如已经提到的，您的函数不是单个表达式。假设您想返回一个字符串元组，可以使用守卫这样编写（以及来自 Arrows 的一些添加的乐趣）：

import Control.Arrow

testx x | x < 0      = "Less then zero."
        | otherwise  = "Greater then or equal to zero."

testy y | y == "foo" = "The name is foo."
        | otherwise  = "The name is not foo."

tester = curry (testx *** testy)

您还可以将 Control.Arrow 位全部删除并写入：

tester x y = (testx x, testy y)