AppleScript：如何启动应用程序然后执行菜单命令

Question

我正在尝试创建一个小 applescript，它将启动 DVD 播放器应用程序，然后将其大小调整为实际大小。代码如下所示。当我运行代码时，DVD 播放器会启动，但不会调整窗口大小。为了让它发挥作用，我缺少什么？

谢谢， 抢

 do_menu("DVD Player", "View", "Actual Size")

on do_menu(app_name, menu_name, menu_item)
    try
        -- bring the target application to the front
        tell application app_name
            activate
        end tell
        delay 3
        tell application "System Events"
            tell process app_name
                tell menu bar 1
                    tell menu bar item menu_name
                        tell menu menu_name
                            click menu item menu_item
                        end tell
                    end tell
                end tell
            end tell
        end tell
        return true
    on error error_message
        return false
    end try
end do_menu

Answer 1

你看过DVD播放器的字典吗？
有用于调整大小的属性。

这将打开它并进入全屏：

tell application "DVD Player"
   open
   delay 2
   set viewer full screen to true
end tell

或者查看器大小属性指出：
查看器大小（一半/正常/双倍/最大）：设置查看器大小

因此您可以使用它转到实际大小：

tell application "DVD Player"
   open
   delay 2
   set viewer size to normal
end tell

这是您想要做的吗？

Answer 2

我不在 Mac 前面，所以我无法真正测试您的代码，但我的建议是尝试相同功能的现有且经过验证的实现，它使用递归而不是嵌套：

http://hints.macworld.com/article.php?story=20060921045743404

也有可能您的delay 3 不够长，无法在您开始尝试编写菜单事件脚本之前完全加载 DVD 播放器应用程序。您可以尝试通过运行两个单独的脚本来调试此问题，并在加载 DVD 播放器应用程序后查看菜单激活代码是否有效。