在 awk 脚本中的搜索模式中使用变量

Question

#!/usr/local/bin/gawk -f  `

{  
awkvar2="/id=22/";  
awkvar3="/end/";  


if ($0 ~ awkvar2) {  
    triggered=1;  
  }  
  if (triggered) {  
     print;  
     if ($0 ~ awkvar3) {  
        triggered=0;  
        print "\n-----------------------------------------------\n"  
     }  
  }  
}  

这个 awk 脚本不适合我 我正在尝试从一行搜索到另一行，即 id=22 直到 end （我不使用 //,// 的原因是因为我想在每个搜索块之后有一个大行） 我希望仅使用变量。
我可以直接使用模式 if ($0 ~ /end/) { 但我不想这样做，我想使用搜索模式内的变量 （原因是我将通过 shell 动态获取变量中的值）

请告诉我如何在 awk 的搜索模式中使用变量

，谢谢...

Answer 1

{
awkvar2="id=22";
awkvar3="end"; 
if ($0 ~ awkvar2) {
        triggered=1;
         }
if (triggered) {
         print;
         if ($0 ~ awkvar3) {
              triggered=0;
              print "\n-----------------------------------------------\n"
         }
}
} 

编辑

根据请求修改以打印“id=22”之前的行

{
  awkvar2="id=22";
  awkvar3="end"; 
  if ($0 ~ awkvar2) {
          print prev;
          triggered=1;
  }
  if (triggered) {
          print;
          if ($0 ~ awkvar3) {
              triggered=0;
              print "\n-----------------------------------------------\n"
          }
  }
  {prev=$0;}
}  

或者，更多笨拙

BEGIN {awkvar2="id=22";awkvar3="end"}

($0 ~ awkvar2),($0 ~ awkvar3) { if ($0 ~ awkvar2) {print prev;}
                                print; 
                                if ($0 ~ awkvar3) {
                                    print "\n---------------\n"
                                }
                               }
{prev=$0;}

Answer 2

belisarius awk 脚本的更紧凑版本，没有“if”

BEGIN {awkvar2="id=22";awkvar3="end"}

($0 ~ awkvar2) {print prev;}
($0 ~ awkvar2),($0 ~ awkvar3) {print; }
($0 ~ awkvar3) {print "\n---------------\n"}
               {prev=$0;}