如何在 Perl 中循环 json 结果

Question

我正在尝试从访问 mysql 数据库的 perl 脚本输出 JSON。

如何循环查询返回并使用 JSON 模块将其转换为 JSON？

当我这样做时，我得到的只是 1 个返回

while($query_handle->fetch()) {
    $jsonStructure->{event};
    $jsonStructure->{event}->{evid} = $evid;
    $jsonStructure->{event}->{component} = $component;
    $jsonStructure->{event}->{firstTime} = $firstTime;
    $jsonStructure->{event}->{lastTime} = $lastTime;
    $jsonStructure->{event}->{count} = $count;
    $jsonStructure->{event}->{summary} = $summary;
    $jsonStructure->{event}->{severity} = $severity;
} 

基本上我有很多事件并且不知道怎么说 event[0]...

谢谢

Answer 1

我认为你正在寻找的是这样的：

push @{ $jsonStructure->{events} }, {
    evid => $evid,
    component => $component,
    ...,
};

尽管即使这样也可能有点过头了，因为你可能可以这样做：

while (my $row = $dbh->fetchrow_hashref) {
  push @{ $jsonStructure->{events} }, $row;
}

如果数据库中的所有列名与 JSON 中你想要的字段名相同，并且你想要所有列，或者：

my @keys = qw(evid component firstTime ...);

while (my $row = $dbh->fetchrow_hashref) {
  my %hash;
  @hash{@keys} = @$row{@keys};
  push @{ $jsonStructure->{events} }, \%hash;
}

如果您只想要某些列，或者：

# DB colname => JSON field name
my %mapping = (
  event_id => 'evid',
  component => 'component',
  first_time => 'firstTime',
  ...,
);

while (my $row = $dbh->fetchrow_hashref) {
  my %hash;
  @hash{ values %mapping } = @$row{ keys %mapping };
  push @{ $jsonStructure->{events} }, \%hash;
}

对于完全任意的映射。 Perl 的力量等等。 :)