刷新access中的链接表

Question

嘿。 我的主访问数据库位于一台脱离网络的独立 PC 上，并且我有一个访问数据库，其网络上的链接表链接回独立 PC。我通过创建到独立 PC 的网络共享并通过路径链接它们来链接这些表。我可以将其设置为在打开数据库时自动更新链接表吗？ 本

Answer 1

你可以。我经常发现使用在启动时运行的小型检查表单（通过启动选项设置）并检查各种内容（包括链接表）很方便。为此，我还在本地机器上保存了一个链接表的表，虽然可以通过迭代TableDefs集合来获取链接表的列表，但我认为保留一个列表稍微安全一些。

检查表单可以检查所有链接，如果链接损坏或丢失，请询问用户新位置或使用固定位置。如果没有发现问题，表单可以自行关闭并打开菜单或其他表单。

在链接到链接表的情况下，可以从以下位置获取要使用的连接：

 CurrentDB.TableDefs("TableName").Connection

以下是更多注意事项：

Sub RelinkTables(Optional strConnect As String = "")
Dim db As DAO.Database
Dim rs As DAO.Recordset
Dim strSQL
Dim tdf As DAO.TableDef

On Error GoTo TrapError

    Set db = CurrentDb

    If strConnect = "" Then
        ''Where Me.txtNewDataDirectory is a control on the check form
        strConnect = "MS Access;PWD=databasepassword;DATABASE=" & Me.txtNewDataDirectory
    End If

    ''Table of tables to be linked with two fields TableName, TableType
    Set rs = CurrentDb.OpenRecordset("Select TableName From sysTables " _
           & "WHERE TableType = 'LINK'")

    Do While Not RS.EOF
        ''Check if the table is missing
        If IsNull(DLookup("[Name]", "MSysObjects", "[Name]='" & rs!TableName & "'")) Then
            Set tdf = db.CreateTableDef(RS!TableName, dbAttachSavePWD, _
                rs!TableName, strConnect)
            ''If the table is missing, append it
            db.TableDefs.Append tdf
        Else
            ''If it exists, update the connection
            db.TableDefs(rs!TableName).Connect = strConnect
        End If
        db.TableDefs(rs!TableName).RefreshLink
        RS.MoveNext
    Loop

    Set db = Nothing
    RS.Close
    Set RS = Nothing


Exit_Sub:
    Exit Sub

TrapError:
    HandleErr Err.Number, Err.Description, "Relink Tables"

End Sub