防止 tcl 线程被主事件循环阻塞

Question

我试图连续运行一个线程，而不让它被 tcl 主事件循环阻塞。 这是我想要做的一个简单示例：

#!/bin/sh
#\
exec tclsh "$0" "$@"

package require Thread

set ::a_thread [thread::create {thread::wait}]

proc start_a {} {
  thread::send $::a_thread {
    puts "Running a thread"
  }
  after 1000 a_start
}

proc infinite_loop {} {
  while {1} {
    puts "Loop"
    after 500
  }
}

start_a
infinite_loop

vwait forever

在此代码中，调用了 infinite_loop 过程，并且主事件循环无限运行。如果 a_thread 仍然可以在后台运行，我希望它。我怎样才能实现这个目标？

Answer 1

主事件循环不会阻塞您的线程。相反，您使用主事件循环来安排要在线程中执行的脚本。相反，在线程本身中运行调度程序：

代码经过测试并按预期工作：

thread::send $::a_thread {
    proc loop {} {
        puts "running a thread"
        after 1000 loop
    }
    loop
}

while 1 {
    puts "loop"
    after 500
}

Answer 2

答案当然是slebetman给出的。但是，调试此类事情（尤其是在更复杂的情况下）的一种方法是在每个线程打印的消息前添加 thread::id，并确保在每次循环的开始处打印一条消息。例如：

package require Thread

set ::a_thread [thread::create {thread::wait}]

proc start_a {} {
  puts "[thread::id]: Dispatch to $::a_thread"
  thread::send $::a_thread {
    puts "[thread::id]: Running a thread"
  }
  after 1000 a_start
}

proc infinite_loop {} {
  while {1} {
    puts "[thread::id]: Loop"
    after 500
  }
}

start_a
infinite_loop
puts "[thread::id]: Start main event loop"
vwait forever

这会告诉您调度只发生一次，另一个线程中的运行是同步发生的（thread::send 默认情况下等待脚本完成执行），并且无限循环阻止主事件循环的启动（从而阻止重新调度调度）。既然你不知道谁在做什么，当然会很混乱！