KRL 中的处理客户端数组提升至 Kynetx 应用程序

Question

概述

我正在构建一个 Kynetx 规则集，它将查找页面上的一堆 Facebook id，然后使用 Kynetx Facebook 模块获取与该 Facebook id 关联的 Facebook 头像。我有在页面上创建 Facebook id 数组的 JS，我可以在 KRL 中处理数组以检索 Facebook 头像。我不知道如何在 KRL 中将数组从客户端获取到服务器端。

如何从 KRL 客户端获取数组到服务器端？

Answer 1

您可以获取 JavaScript 数组并将其转换为字符串，如果您解码它，它就会工作在 KRL 的服务器端。

示例应用程序代码=> https://gist.github.com/722536

示例应用书签 => http://mikegrace. s3.amazonaws.com/forums/stack-overflow/send-array-to-kns-dev-bookmarklet.html

ruleset a60x442 {
  meta {
    name "array-passing-test"
    description <<
      array-passing-test
    >>
    author "Mike Grace"
    logging on
  }

  rule start_your_engines {
    select when pageview ".*"
    {
      notify("Running","...sending array to KNS") with sticky = true;
      emit <|
        app = KOBJ.get_application("a60x442");
        var numbers = [1,2,3,4,5];
        nums = JSON.stringify(numbers);
        app.raise_event("process_array", {"numbers":nums});
        $K("div.KOBJ_message").append("<br/>"+nums);
      |>;
    }
  }

  rule process_array {
    select when web process_array
    foreach event:param("numbers").decode() setting (number)
    {
      notify("number",number) with sticky = true;
    }
  }
}

从 http://example.com/

Answer 2

回答

不幸的是，KRL JS 运行时尚不支持将数组发送到服务器端。有一种方法可以完成您想做的事情。

示例

我构建了一个示例应用程序，该应用程序在此页面上运行，并带有一个书签，该书签获取问题所标记的标签，并将它们发送到服务器进行处理，然后返回。

示例应用代码 => https://gist.github.com/707561

示例应用书签 = > http://mikegrace. s3.amazonaws.com/forums/stack-overflow/client-side-array-to-server-bookmarklet.html

代码示例的逐步说明

1. 收集 JS 数组中的文本
2. 将数组转换为 csv 字符串并将逗号附加到使正则表达式拆分更容易
3. 使用 csv 字符串将事件引发到 KNS
4. 处理规则将第一个值
5. 从其余值保存到新变量
6. 第一个值进入通知
7. postlude 将剩余值发送到自身
8. 循环直到完成并将指令返回到浏览器

结果从书签运行应用程序的结果：

Answer 3

如果您对哈希数组进行 JSON.stringify，则还可以执行哈希数组。

示例应用：

ruleset a60x449 {
  meta {
    name "pass-hash-in-web-event-test"
    description <<
      pass-hash-in-web-event-test
    >>
    author "Mike Grace"
    logging on
  }

  rule start_this_party {
    select when pageview ".*"
    {
      notify("Now running","Building arrays to send to KNS") with sticky = true;
      emit <|
        var data = {};
        data.userData = JSON.stringify(
          [
            {"name":"MikeGrace","id":234232344},
            {"name":"TelegramSam","id":234089790234},
            {"name":"Alex","id":2300234234234}
          ]
        );
        app = KOBJ.get_application("a60x449");
        app.raise_event("process_me_data", data);
      |>;
    }
  }

  rule process_arrays_of_data {
    select when web process_me_data
    foreach event:param("userData").decode() setting (user)
    pre {
      userName = user.pick("$.name");
      userId = user.pick("$.id");
      output =<<
        <p>
          userName: #{userName}<br/>
          userId: #{userId}<br/>
        </p>
      >>;
    }
    {
      append("body", output);
    }
  }
}

在 example.com 上运行的结果