Prolog 中的简单 nth1 谓词

Question

在 SWI Prolog 中，有一个谓词可以查找名为 nth1 的列表中的第 n 个项目。我想实现我自己的谓词版本，但如果您查看清单（nth1）代码，SWI 的版本会非常复杂。有更简单的方法吗？

谢谢 ：）。

Answer 1

考虑对一般（可逆）整数运算使用有限域约束：

:- use_module(library(clpfd)).

nth1(1, [E|_], E).
nth1(N, [_|Xs], E) :-
        N #> 1,
        N #= N1 + 1,
        nth1(N1, Xs, E).

Answer 2

我并不是故意要自相矛盾或者让别人来真正做我的工作；我只是想要一些建议，抱歉没有说得更清楚。

我现在已经自己实现了它，但是你们能建议改进或更好的方法吗？我经常发现自己在 Prolog 中做的事情是编写一个带有一个或一组计数器的谓词，并使用较少参数的谓词来调用带有额外参数的子句。这通常最终会产生相当多的代码。不管怎样，这是我刚刚完成的实现：

item_at( N, L, Item ) :-
    item_at( N, 0, L, Item ).   
item_at( N, Count, [H|_], Item ) :-
    CountNew is Count + 1,
    CountNew = N,
    Item = H.
item_at( N, Count, [_|T], Item ) :-
    CountNew is Count + 1,
    item_at( N, CountNew, T, Item ).

有什么意见吗？谢谢 ：）。用法：

?- item_at(3,[a,b,c,d,e],Item).
Item = c ;

Answer 3

SWI 代码有点复杂，因为谓词可用于从变量索引生成：

?- nth1(Idx,[a,b,c],X).
Idx = 1,
X = a ;
Idx = 2,
X = b ;
Idx = 3,
X = c ;
false.

如果您不想要这种行为，可以根据 nth0 轻松实现 nth1/3：

nth1(Idx,List,X) :-
    Idx0 is Idx-1,
    nth0(Idx0,List,X).

编辑：也可以不用 nth0 只需几行代码即可完成：

nth1(1,[X|_],X) :- !.
nth1(Idx,[_|List],X) :-
    Idx > 1,
    Idx1 is Idx-1,
    nth1(Idx1,List,X).