如何使用 LWP 发出 JSON POST 请求？

Question

如果您尝试登录 https://orbit.theplanet.com/Login.aspx?url=/ Default.aspx（使用任何用户名/密码组合），您可以看到登录凭据作为一组非传统的 POST 数据发送：只是一个孤独的 JSON 字符串，没有正常的键=值对。

具体来说，而不是：

username=foo&password=bar

甚至类似：

json={"username":"foo","password":"bar"}

很简单：

{"username":"foo","password":"bar"}

是否可以使用 LWP 或替代模块执行此类请求？我准备使用 IO::Socket 来实现这一点，但如果有的话，我更喜欢更高级的东西。

Answer 1

您需要手动构建 HTTP 请求并将其传递给 LWP。应该执行类似以下操作：

my $uri = 'https://orbit.theplanet.com/Login.aspx?url=/Default.aspx';
my $json = '{"username":"foo","password":"bar"}';
my $req = HTTP::Request->new( 'POST', $uri );
$req->header( 'Content-Type' => 'application/json' );
$req->content( $json );

然后您可以使用 LWP 执行请求：

my $lwp = LWP::UserAgent->new;
$lwp->request( $req );

Answer 2

只需创建一个 POST 请求并将其作为正文，然后将其交给 LWP。

my $req = HTTP::Request->new(POST => $url);
$req->content_type('application/json');
$req->content($json);

my $ua = LWP::UserAgent->new; # You might want some options here
my $res = $ua->request($req);
# $res is an HTTP::Response, see the usual LWP docs.

Answer 3

该页面仅使用“匿名”（无名称）输入，该输入恰好采用 JSON 格式。

您应该能够使用 $ua->post($url , ..., Content => $content)，这又使用 HTTP::Request::Common。

use LWP::UserAgent;

my $url = 'https://orbit.theplanet.com/Login.aspx?url=/Default.aspx';
my $json = '{"username": "foo", "password": "bar"}';

my $ua = new LWP::UserAgent();
$response = $ua->post($url, Content => $json);

if ( $response->is_success() ) {
    print("SUCCESSFUL LOGIN!\n");
}
else {
    print("ERROR: " . $response->status_line());
}

或者，您也可以对 JSON 输入使用哈希：

use JSON::XS qw(encode_json);

...

my %json;
$json{username} = "foo";
$json{password} = "bar";

...

$response = $ua->post($url, Content => encode_json(\%json));

Answer 4

如果您确实想使用 WWW::Mechanize 您可以在发布之前设置标题“content-type”

$mech->add_header( 
'content-type' => 'application/json'
);

$mech->post($uri, Content => $json);