用于确定应用程序是否在 Citrix 或终端服务上运行的 API

Question

Closed. This question is seeking recommendations for software libraries, tutorials, tools, books, or other off-site resources. It does not meet Stack Overflow guidelines. It is not currently accepting answers.

---

我们不允许提出寻求软件库、教程、工具、书籍或其他场外资源推荐的问题。您可以编辑问题，以便用事实和引文来回答。

6 年前已关闭。

Answer 1

有一个 API 函数可让您确定特定的用户会话是显示在控制台上（本地）还是通过远程协议 Citrix ICA（现在称为 HDX）或 Microsoft RDP 之一显示。

调用 WTSQuerySessionInformation，并将第三个参数设置为 WTSClientProtocolType。该函数返回：

• 0（控制台会话）
• 1（ICA 会话）
• 2（RDP 会话）

有趣的是，返回值 1 在 MSDN（上面的第二个链接）上不再记录为 WTS_PROTOCOL_TYPE_ICA，而是记录为“此值是保留用于遗留目的。”。

更新：

XenDesktop 无法使用 WTSQuerySessionInformation 检测会话（它返回 0，表示控制台）。如果您想要通用解决方案：

• 调用 WTSQuerySessionInformation。如果返回 1 或 2（ICA 或 RDP），则您已完成。
• 如果WTSQuerySessionInformation返回0（控制台），则动态加载wfapi.dll并获取WFGetActiveProtocol的地址
• 调用WFGetActiveProtocol WF_CURRENT_SESSION 参数，定义为 ((DWORD)-1)
• WFGetActiveProtocol 的返回值为会话类型。它应该是 0（控制台）或 1（ICA）

我已经详细描述了该过程 此处以及 C++ 代码示例和返回当前会话的远程处理协议类型的工作编译工具。

Answer 2

根据： http://forums.citrix.com/message.jspa?messageID=1363711< /a> 您可以检查SESSIONNAME环境变量。

另一种更简单的方法是读取系统环境变量“SESSIONNAME”。如果它存在并且以“ICA”开头，那么您正在 Citrix 会话中运行。如果它以“RDP”开头，那么您正在 RDP 会话中运行。

我用我的电脑测试了它，并在本地得到：

C:\>echo %SESSIONNAME%
Console

虽然远程我得到了

C:\>echo %SESSIONNAME%
RDP-tcp1

所以这似乎是一条简单的路线，否则听起来像检查注册表值或某些 dll 是否存在将是下一个最好的事情。

Answer 3

按照@Josh的回答，代码将如下所示：

Select Case Environment.GetEnvironmentVariable("SessionName").ToUpper.SubString(0,3))
   Case "ICA" 
      bCitrix = True
   Case "RDP"
      bTerminalServer = True
   Case "CON" 
      bPC = True
End Select

我还没有完全测试它，但看起来它会做我想要的事情。 PC 和终端服务器正确报告。

如果有人有办法在 Citrix 盒子上测试这一点，我们将不胜感激！

Answer 4

根据 Helge Klein 的修订答案（上面），我想我应该发布 VBA 代码来实现这一点，以帮助未来的 VBA 用户点击此页面。 Helge 已经在他自己的网站上有了 C++ 代码。如果您觉得这有帮助，请为 Helge Klein 的回答点赞。

Option Explicit

Private Const WTS_CURRENT_SERVER_HANDLE = 0&
Private Const WTS_CURRENT_SESSION As Long = -1

Private Enum WTS_INFO_CLASS
    WTSInitialProgram
    WTSApplicationName
    WTSWorkingDirectory
    WTSOEMId
    WTSSessionId
    WTSUserName
    WTSWinStationName
    WTSDomainName
    WTSConnectState
    WTSClientBuildNumber
    WTSClientName
    WTSClientDirectory
    WTSClientProductId
    WTSClientHardwareId
    WTSClientAddress
    WTSClientDisplay
    WTSClientProtocolType
    WTSIdleTime
    WTSLogonTime
    WTSIncomingBytes
    WTSOutgoingBytes
    WTSIncomingFrames
    WTSOutgoingFrames
    WTSClientInfo
    WTSSessionInfo
    WTSSessionInfoEx
    WTSConfigInfo
    WTSValidationInfo
    WTSSessionAddressV4
    WTSIsRemoteSession
End Enum

Private Declare Function WTSQuerySessionInformation _
    Lib "wtsapi32.dll" Alias "WTSQuerySessionInformationA" ( _
    ByVal hServer As Long, ByVal SessionId As Long, _
    ByVal WtsInfoClass As WTS_INFO_CLASS, _
    ByRef ppBuffer As LongPtr, _
    ByRef pBytesReturned As LongPtr _
    ) As Long

Private Declare Function WFGetActiveProtocol _
    Lib "wfapi.dll" ( _
    ByVal SessionId As Long _
    ) As Long

Private Declare Sub WTSFreeMemory Lib "wtsapi32.dll" ( _
    ByVal pMemory As Long)

Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" ( _
    Destination As Any, Source As Any, ByVal length As Long)

Public Function SessionType() As String
    Dim ResultCode As Long
    Dim p As LongPtr
    Dim ppBuffer As LongPtr
    Dim pBytesReturned As Long
    Dim ClientProtocolType As Integer
    ResultCode = WTSQuerySessionInformation(WTS_CURRENT_SERVER_HANDLE, WTS_CURRENT_SESSION, WTSClientProtocolType, ppBuffer, pBytesReturned)

    If ResultCode = 0 Then
        p = ppBuffer
        CopyMemory ClientProtocolType, ByVal p, pBytesReturned
        WTSFreeMemory ppBuffer
    End If

    Select Case ClientProtocolType
      Case 0:
        On Error Resume Next
        ResultCode = WFGetActiveProtocol(WTS_CURRENT_SESSION)
        If Err.Number = 53 Then
          SessionType = "Console"
        ElseIf Err.Number = 0 Then
          If ResultCode = 1 Then
            SessionType = "Citrix"
          Else
            SessionType = "Console"
          End If
        End If
        Err.Clear
        On Error GoTo 0
      Case 1:
        SessionType = "Citrix"
      Case 2:
        SessionType = "RDP"
      Case Else
        SessionType = "Other (" & ClientProtocolType & ")"
    End Select
End Function

我已经在 XenApp 和 XenDesktop 上对此进行了测试。