如何使用值数组初始化向量？

Question

如何使用值数组初始化向量？

我尝试了这个，它符合要求，但不起作用！

 langs = new Vector.<String>(["en","fr"]);

我还需要将任意数组加载到向量中，如下所示：

 langlist = ["en","fr"];
 langs = new Vector.<String>(langlist);

有办法做到这一点吗？

---

编辑：如何使用 2D 值数组初始化 2D 向量？

 numbers = [[10,20,30], [10,20,30]];
 nums = Vector.<Vector.<Number>>(numbers);

我尝试了这个，但它给了我错误：

TypeError：错误#1034：类型强制失败

Answer 1

初始化字符串向量的适当语法是这样的：

var langs:Vector.<String> = new <String>[ "en","fr" ];

为了创建多维向量，请使用以下语法：

var v:Vector.<Vector.<int>> = new <Vector.<int>>[ new <int>[ 1, 2, 3 ], new <int>[ 4, 5, 6 ] ];

请注意，以下语法可以工作，但不太理想，因为它首先生成一个数组，然后将其转换为向量，这样速度较慢，对于非常大的数组有问题，并且不支持多维向量。

var langs:Vector.<String> = Vector.<String>( [ "en","fr" ] );

Answer 2

您可以使用 Vector.。 html#Vector%28%29" rel="nofollow">Vector. 全局函数：

var vec : Vector.<String> = Vector.<String>(["en","fr"]);

Answer 3

我认为您不能将数组数组传递到 Vector 中：

Vector.<Vector.<Number>>

类型强制不适用于复杂类型。如果您已经有了二维数组，请考虑以下转换代码：

var numbers:Array = [[1, 2, 3], [4, 5, 6]];
var numbersTemp:Array =
numbers.map(
    function (element:*, index:int, arr:Array):Vector.<Number> {
    return Vector.<Number>(element);
});
var nums:Vector.<Vector.<Number>> = Vector.<Vector.<Number>>(numbersTemp);

当然，这将导致所有内容的新副本被创建两次，因此理想情况下您不会转换大列表。

Answer 4

从值列表初始化 Vector 的最干净、最快和最类型安全的方法是：

langs = new <String> ["en","fr"];

它不会创建临时数组来初始化新的 Vector，因此它将生成最快的字节码，并且不会打扰垃圾收集器无用的临时数组实例化。它和 一样快，但更实用：

langs = new Vector.<String>(2);
langs[0] = "en";
langs[1] = "fr";

最重要的是，它将在编译时执行类型检查，并减少出现运行时错误的机会。

对于 2D 向量，没有直接语法，因此您必须显式创建每个向量Vector：

nums = new <Vector.<Number> > [new <Number>[10,20,30], new <Number>[10,20,30]];

您可以在这里深入了解非空 Vector 初始化的性能以及为什么其他解决方案速度较慢：

http: //jacksondunstan.com/articles/702

PS：如果右括号没有用空格分隔，较旧的 mxmlc 编译器将无法理解右括号：

new >