Fastreports自定义预览问题

Question

我在 FastReports 上遇到问题，它无法在包含韩语字符的页面上正确打印。仅在 HP K5300 jet 打印机上出现这种情况，使用 rave 对其进行了测试，没有问题。我认为这是快速报告的一个错误。我已经将所有报告从 rave 转换为 FastReports，并且没有计划移回。

我计划将生成的页面作为图像获取，而不将其保存到硬盘驱动器，然后生成新的预报告。这次，将使用并打印生成的图像。我知道这个解决方案不好。在等待他们的答复时，这是目前可行的。

有人知道如何从生成的页面获取图像吗？

Answer 1

如果您只是想避免保存大量文件，可以创建一个新的导出类，以便在文件创建后立即打印并立即将其删除。

您可以创建一个全新的导出类，从内存中打印位图（例如，使用 TPrinter 类并直接在打印机画布中绘制位图）...您将了解如何检查 TfrxBMPExport 类的源文件。

以这段未经测试的代码为例，它将指导您如何创建一个新类来保存/打印/删除：

type
  TBMPPrintExport = class(TfrxBMPExport)
  private
    FCurrentPage: Integer;
    FFileSuffix: string;
  protected
    function Start: Boolean; override;
    procedure StartPage(Page: TfrxReportPage; Index: Integer); override;
    procedure Save; override;
  end;


{ TBMPPrintExport }

procedure TBMPPrintExport.Save;
var
  SavedFileName: string;
begin
  inherited;
  if SeparateFiles then
    FFileSuffix := '.' + IntToStr(FCurrentPage)
  else
    FFileSuffix := '';
  SavedFileName := ChangeFileExt(FileName, FFileSuffix + '.bmp');
  //call your actual printing routine here.  Be sure your the control returns here when the bitmap file is not needed anymore.
  PrintBitmapFile(SavedFileName);
  try
    DeleteFile(SavedFileName);
  except
    //handle exceptions here if you want to continue if the file is not deleted 
    //or let the exception fly to stop the printing process.
    //you may want to add the file to a queue for later deletion
  end;
end;

function TBMPPrintExport.Start: Boolean;
begin
  inherited;
  FCurrentPage := 0;
end;

procedure TBMPPrintExport.StartPage(Page: TfrxReportPage; Index: Integer);
begin
  inherited;
  Inc(FCurrentPage);
end;

在生产代码中，您将需要重写其他方法来初始化和完成打印机作业、清理等。

代码基于在 FastReport v4.0 上实现了 TfrxCustomImageExport，专门用于页码和文件命名。它可能需要针对其他 FastReport 版本进行调整。

Answer 2

您可以使用 TfrxBMPExport（frxExportImage 单元）组件将报表保存为 BMP。

例如，此代码将导出报告：

procedure ExportToBMP(AReport: TfrxReport; AFileName: String = '');
var
  BMPExport: TfrxBMPExport;

begin
  BMPExport := TfrxBMPExport.Create(nil);
  try
    BMPExport.ShowProgress := True;
    if AFileName <> '' then
    begin
      BMPExport.ShowDialog := False;
      BMPExport.FileName := AFileName;
      BMPExport.SeparateFiles := True;
    end;
    AReport.PrepareReport(True);
    AReport.Export(BMPExport);
  finally
    BMPExport.Free;
  end;
end;

在本例中，导出组件为每个页面使用不同的文件名。如果您传递“c:\path\report.bmp”作为文件名，导出组件将生成 c:\path\report.1.bmp、c:\path\report.2.bmp 等。

与往常一样，如果您愿意，可以在任何表单/数据模块上删除并手动配置该组件。