在 VBA 中从数组创建 CSV

Question

我是一名新手程序员，试图自动化一些重复的工作场所任务，这些任务应该由聪明的脚本而不是人类来完成。我已经完成了一些 VBA 和 Java，但都是非常基础的东西。

我们有一些由经过验证的在线表单生成的数据，这些数据通过电子邮件发送到邮箱，然后邮件客户端 (Outlook 2010) 中的过滤器将其放入特定文件夹中。我的目的是编写一些 VBA，当触发时将检查该文件夹的内容，然后对于每个邮件项目，以字符串形式获取邮件正文文本，创建一个数组，然后将数组内容写入 .csv 文件。然后，我将让另一个应用程序（适用于 Firefox 的 iMacros）读取 csv 并与内部企业 Web 应用程序交互来完成其余的工作。

我想我可以做所有这些，除了将数组内容写入 csv 之外。

我通过查看代码示例（我确实尝试理解 MS 对象模型文档）来工作得最好，但是我能找到的将 VBA 数组写入 CSV 的最好方法是：

  'save the file
  Open sFileName For Output As #7
  For n = 0 To UBound(MyArray, 1)
    Print #7, Format(MyArray(n, 0), "0.000000E+00")
  Next n
  Close #7

我认为这是 VB 而不是 VBA，但是这里的总体想法有效吗？或者，如果其他人有一个代码示例来帮助我入门或任何其他指示，我将非常感激。

PS还看到如何保存二维数组作为 csv 文件？ 但无法理解它。

Answer 1

下面的代码适用于将二维数组转换为 CSV。我没有编写代码，但已经测试过它并且有效！

' SaveAsCSV saves an array as csv file. Choosing a delimiter different as a comma, is optional.
'
' Syntax:
' SaveAsCSV dMyArray, sMyFileName, [sMyDelimiter]
'
' Examples:
' SaveAsCSV dChrom, app.path & "\Demo.csv"       --> comma as delimiter
' SaveAsCSV dChrom, app.path & "\Demo.csv", ";"  --> semicolon as delimiter
'
' Rev. 1.00 [8 jan 2003]
' written by P. Wester
' [email protected]


Public Sub SaveAsCSV(MyArray() As Variant, sFilename As String, Optional sDelimiter As String = ",")

Dim n As Long 'counter
Dim M As Long 'counter
Dim sCSV As String 'csv string to print

On Error GoTo ErrHandler_SaveAsCSV


'check extension and correct if needed
If InStr(sFilename, ".csv") = 0 Then
  sFilename = sFilename & ".csv"
Else
  While (Len(sFilename) - InStr(sFilename, ".csv")) > 3
    sFilename = Left(sFilename, Len(sFilename) - 1)
  Wend
End If

'If MultiDimensional(MyArray()) = False Then '1 dimension

  'save the file
'  Open sFileName For Output As #7
'  For n = 0 To UBound(MyArray(), 1)
'    Print #7, Format(MyArray(n, 0), "0.000000E+00")
'  Next n
'  Close #7

'Else 'more dimensional

  'save the file
  Open sFilename For Output As #7
  For n = 1 To UBound(MyArray(), 1)
    sCSV = ""
    For M = 1 To UBound(MyArray(), 2)
      sCSV = sCSV & Format(MyArray(n, M)) & sDelimiter
    Next M
    sCSV = Left(sCSV, Len(sCSV) - 1) 'remove last Delimiter
    Print #7, sCSV
  Next n
  Close #7

'End If

Exit Sub


ErrHandler_SaveAsCSV:
  Close #7

Answer 2

我不使用 VB，所以我不确定输出 #7 的打开文件，但如果它有效（使用一些随机输出测试它），那么您的代码片段是正确的。唯一的问题是您应该进行另一个 Print 调用，其中添加一个“，”。

只要确保在最后一次迭代中没有添加“，”即可。您可以通过添加一个 If 语句来检查是否 n = UBound(MyArray) - 1 （这是最后一个元素的索引。）

希望它有帮助，

PM

Answer 3

这是一个基于 Excel 的解决方案。如果您从 Excel 控制 Outlook，这可能是一个可行的解决方案。此外，如果您正在开发 Excel 项目，这可能会有用。

Private Sub ArrayToCsvWorkborkMethod(MyArray As Variant, FileName As String)
Application.ScreenUpdating = False
Application.DisplayAlerts = False
Dim WB As Workbook
Set WB = Application.Workbooks.Add
Dim WS As Worksheet
Set WS = WB.Sheets(1)

Dim Target As Range
Set Target = Range("A1").Resize(UBound(MyArray, 1), UBound(MyArray, 2))
Target.Value = MyArray
WB.SaveAs FileName, 23
WB.Close
Application.ScreenUpdating = True
Application.DisplayAlerts = True
End Sub

我是这样解决的。这速度较慢，但​​消除了先前解决方案可能出现的任何奇怪的格式。
这将创建一个新工作簿，将数组写入工作表，将该新工作簿另存为 CSV 文件，然后关闭新工作簿。

至少对我来说，这工作起来更加可靠，并且可以消除任何格式问题，从而变得更加出色。