Groovy 读取目录中的最新文件

Question

我只是有一个关于编写一个函数的问题，该函数将在目录中搜索目录中的最新日志。我目前想出了一个，但我想知道是否有更好（也许更合适）的方法来做到这一点。

我目前正在使用 hdsentinel 在计算机上创建日志并将日志放置在目录中。日志的保存方式如下：

/directory/hdsentinel-computername-date

ie. C:/hdsentinel-owner-2010-11-11.txt

因此，我编写了一个快速脚本，该脚本循环访问某些变量以检查最近的变量（过去一周内），但在查看它之后，我怀疑这样做的效率和正确性如何方式。

这是脚本：

String directoryPath = "D:"
def computerName = InetAddress.getLocalHost().hostName
def dateToday = new Date()
def dateToString = String.format('%tm-%<td-%<tY', dateToday)
def fileExtension = ".txt"
def theFile


for(int i = 0; i < 7; i++) {
    dateToString = String.format('%tY-%<tm-%<td', dateToday.minus(i))
    fileName = "$directoryPath\\hdsentinel-$computerName-$dateToString$fileExtension"

    theFile = new File(fileName)

    if(theFile.exists()) {
        println fileName
        break;
    } else {
        println "Couldn't find the file: " + fileName
    }
}

theFile.eachLine { print it }

该脚本工作正常，也许有一些缺陷。我觉得我应该在继续之前询问此类事情的典型路线是什么。

感谢所有的意见。

Answer 1

虽然有点混乱，但您可以通过“groupBy”方法实现多列排序（阐述 Aaron 的代码）。

def today = new Date()
def recent = {file -> today - new Date(file.lastModified()) < 7}

new File('/yourDirectory/').listFiles().toList()
.findAll(recent)
.groupBy{it.name.split('-')[1]}
.collect{owner, logs -> logs.sort{a,b -> a.lastModified() <=> b.lastModified()} }
.flatten()
.each{ println "${new Date(it.lastModified())}  ${it.name}" } 

这会找到上周创建的所有日志，按所有者名称对它们进行分组，然后根据修改日期进行排序。

如果目录中还有日志以外的文件，则可能首先需要 grep 查找包含“hdsentinel”的文件。

我希望这有帮助。

编辑：
从您提供的示例中，我无法确定格式中的最低有效数字是否为：

C:/hdsentinel-owner-2010-11-11.txt

代表月份或日期。如果是后者，按文件名排序将自动按所有者排序，然后按创建日期排序（没有上述代码的所有欺骗行为）。

例如：

new File('/directory').listFiles().toList().findAll(recent).sort{it.name}

Answer 2

希望这对一些人有帮助......这以更常规的方式按修改日期对给定路径进行排序。列出了它们。

您可以限制列表，并在闭包中添加其他条件以获得所需的结果

 new File('/').listFiles().sort() {
   a,b -> a.lastModified().compareTo b.lastModified()
 }.each {
     println  it.lastModified() + "  " + it.name
 } 

Answer 3

当我试图解决类似的问题时，学习了一种更简洁的方法。

定义一个用于排序的闭包

def fileSortCondition = { it.lastModified() }

File.listFiles() 还有其他变体，它接受 Java 中的 FileFilter 和 FilenameFilter，并且这些接口有一个名为accept的方法，将接口实现为闭包。

def fileNameFilter = { dir, filename ->
if(filename.matches(regrx))
    return true
else
    return false
} as FilenameFilter

最后，

new File("C:\\Log_Dir").listFiles(fileNameFilter).sort(fileSortCondition).reverse()

如果要通过文件属性完成过滤，请实现 FileFilter 接口。

def fileFilter = {  file ->
        if(file.isDirectory())
             return false 
        else
            return true }  as FileFilter