如何从 COM 服务器返回 WideString？

Question

_TLB.pas 文件中的此接口

// *********************************************************************//
// Interface: ITMyCOM
// Flags: (256) OleAutomation
// GUID: {D94769D0-F4AF-41E9-9111-4D8BC2F42D69}
// *********************************************************************//
ITMyCOM = interface(IUnknown)
['{D94769D0-F4AF-41E9-9111-4D8BC2F42D69}']
function MyDrawWS(a: Integer; b: Integer): WideString; stdcall;
end;

这会查看

[
odl,
uuid(D94769D0-F4AF-41E9-9111-4D8BC2F42D69),
version(1.0),
helpstring("Interface for TMyCOM Object"),
oleautomation
]
interface ITMyCOM : IUnknown {
BSTR _stdcall MyDrawWS(
[in] long a, 
[in] long b);
};

COM 服务器中的操作系统 Windows 函数，看起来就像

function TTMyCOM.MyDrawWS(a, b: Integer): WideString;
begin
Result := WideString(IntToStr(a+b));
end;

在 COM 客户端中，我正在调用此函数

Edit1.Text := String(MyCOM.MyDrawWS(1,1));

，并收到错误第一次机会异常，位于 $75A9FBAE。异常类 EAccessViolation，带有消息“模块‘RPCRT4.dll’中地址 75A409A4 处的访问冲突”。读取地址 FFFFFFF8'。 Process Project1.exe (2296)

如果我想返回 Integer，这是可行的。如何返回宽字符串？

Answer 1

处理这个问题的正确方法如下：

[ 
odl, 
uuid(D94769D0-F4AF-41E9-9111-4D8BC2F42D69), 
version(1.0), 
helpstring("Interface for TMyCOM Object"), 
oleautomation 
] 
interface ITMyCOM : IUnknown { 
HRESULT _stdcall MyDrawWS( 
[in] long a,  
[in] long b,
[out, retval] BSTR* ret); 
}; 

ITMyCOM = interface(IUnknown) 
  ['{D94769D0-F4AF-41E9-9111-4D8BC2F42D69}'] 
  function MyDrawWS(a: Integer; b: Integer; out ret: WideString): HResult; stdcall; 
end; 

function TTMyCOM.MyDrawWS(a, b: Integer; out ret: WideString): HRESULT; 
begin 
  ret := IntToStr(a+b);
  Result := S_OK;
end; 

var
  W: WideString;
begin
  OleCheck(MyCOM.MyDrawWS(1, 1, W));
  Edit1.Text := W;
end;

然后可以通过在接口的 Delphi 声明（而不是 TypeLibrary 本身）中使用 Delphi 的 safecall 调用约定来稍微简化：

ITMyCOM = interface(IUnknown) 
  ['{D94769D0-F4AF-41E9-9111-4D8BC2F42D69}'] 
  function MyDrawWS(a: Integer; b: Integer): WideString; safecall;
end; 

function TTMyCOM.MyDrawWS(a, b: Integer): WideString;
begin 
  Result := IntToStr(a+b);
end; 

Edit1.Text := MyCOM.MyDrawWS(1, 1);

Answer 2

让 Delphi 自动执行转换。别投。您可以将 (ansi) 字符串转换为 PChar，因为它们的内存布局是兼容的，但您不能将字符串转换为宽字符串，反之亦然。当您将一个分配给另一个时，Delphi 将执行转换。

在德尔福< 2009年

var
S: string;
W: WideString;
...
S := W;  // Conversion, WideString -> AnsiString;
W := S; // Conversion, AnsiString -> WideString

Answer 3

不要使用 HRESULT 以外的返回值。而是将您的返回值作为输出参数放入参数列表中。

function MyDrawWS(a: Integer; b: Integer; out str : WideString): HRESULT; stdcall;

这样，你也被迫使用COM内存管理器IMalloc（CoTaskMemAlloc用于pur COM，SysAllocString用于Automation）。

Answer 4

您需要使用 SysAllocString() 或SysAllocStringLen() 分配 BSTR。

Answer 5

第一次机会例外，价格为 75A9FBAE。异常类 EAccessViolation，带有消息“模块‘RPCRT4.dll’中地址 75A409A4 处的访问冲突

1. 错误来自 RPCRT4.dll

2. EAccessViolation 主要是由访问引起的如果是 null 对象，请单步执行您的代码，确保所有对象都是有效对象。