F# System.OutOfMemoryException 与递归调用

Question

这实际上是 F# 中 Project Euler 问题 14 的解决方案。但是，在尝试计算较大数字的迭代序列时，我遇到了 System.OutOfMemory 异常。如您所见，我正在使用尾部调用编写递归函数。

我遇到了 StackOverFlowException 的问题，因为我正在 Visual Studio 中进行调试（这会禁用尾部调用）。我已经在另一个问题中记录了这一点。在这里，我在发布模式下运行 - 但当我将其作为控制台应用程序运行时（在具有 4GB RAM 的 Windows XP 上），我遇到了内存不足的异常。

我真的不明白我是如何将自己编码成这种内存溢出&的。希望有人能以我的方式向我指出错误。

let E14_interativeSequence x =

  let rec calc acc startNum =
    match startNum with
    | d when d = 1      -> List.rev (d::acc)
    | e when e%2 = 0    -> calc (e::acc) (e/2)
    | _                 -> calc (startNum::acc) (startNum * 3 + 1)

  let maxNum pl=

    let rec maxPairInternal acc pairList =
        match pairList with
        | []        ->  acc
        | x::xs     ->  if (snd x) > (snd acc) then maxPairInternal x xs
                        else maxPairInternal acc xs

    maxPairInternal (0,0) pl
    |> fst

  // if I lower this to like [2..99999] it will work.
  [2..99999] 
  |> List.map (fun n -> (n,(calc [] n)))
  |> List.map (fun pair -> ((fst pair), (List.length (snd pair))))
  |> maxNum
  |> (fun x-> Console.WriteLine(x))

---

编辑

鉴于答案中的建议，我重写了使用惰性列表并使用 Int64 的列表。

#r "FSharp.PowerPack.dll"

let E14_interativeSequence =

  let rec calc acc startNum =
    match startNum with
    | d when d = 1L         -> List.rev (d::acc) |> List.toSeq
    | e when e%2L = 0L      -> calc (e::acc) (e/2L)
    | _                     -> calc (startNum::acc) (startNum * 3L + 1L)

  let maxNum (lazyPairs:LazyList<System.Int64*System.Int64>) =

    let rec maxPairInternal acc (pairs:seq<System.Int64*System.Int64>) =
        match pairs with
        | :? LazyList<System.Int64*System.Int64> as p ->
            match p with
            | LazyList.Cons(x,xs)->  if (snd x) > (snd acc) then maxPairInternal x xs
                                     else maxPairInternal acc xs
            | _                         ->  acc
        | _ -> failwith("not a lazylist of pairs")

    maxPairInternal (0L,0L) lazyPairs
    |> fst

  {2L..999999L}
  |> Seq.map (fun n -> (n,(calc [] n)))
  |> Seq.map (fun pair -> ((fst pair), (Convert.ToInt64(Seq.length (snd pair)))))
  |> LazyList.ofSeq
  |> maxNum

这解决了问题。不过，我也会看看 Yin Zhu 的解决方案，这是更好的解决方案。

Answer 1

正如 Brian 所提到的，List.* 操作在这里不合适。它们消耗了太多的内存。

stackoverflow问题来自另一个地方。有两种可能的 stackoverflow：calc 和 maxPairInternal。它必须是第一个，因为第二个与第一个具有相同的深度。然后问题就到了数字，3n+1问题中的数字很容易变得非常大。所以你首先会得到一个 int32 溢出，然后你会得到一个 stackoverflow。这就是原因。将数字更改为 64 位后，程序可以运行。

这是我的解决方案页面，您可以在其中看到记忆技巧。

open System
let E14_interativeSequence x =

  let rec calc acc startNum =
    match startNum with
    | d when d = 1L      -> List.rev (d::acc)
    | e when e%2L = 0L    -> calc (e::acc) (e/2L)
    | _                 -> calc (startNum::acc) (startNum * 3L + 1L)

  let maxNum pl=

    let rec maxPairInternal acc pairList =
        match pairList with
        | []        ->  acc
        | x::xs     ->  if (snd x) > (snd acc) then maxPairInternal x xs
                        else maxPairInternal acc xs

    maxPairInternal (0L,0) pl
    |> fst

  // if I lower this to like [2..99999] it will work.
  [2L..1000000L] 
  |> Seq.map (fun n -> (n,(calc [] n)))
  |> Seq.maxBy (fun (n, lst) -> List.length lst)
  |> (fun x-> Console.WriteLine(x))

Answer 2

如果将 List.map 更改为 Seq.map （并重新工作 maxPairInternal 以迭代 seq），这可能会有所帮助。现在，您在处理整个结构以获得单个数字结果之前，首先在一个巨大的结构中显示所有数据。最好通过 Seq 惰性地执行此操作，只需创建一行，然后将其与下一行进行比较，一次创建一行然后丢弃它。

我现在没有时间编写我的建议，但如果您仍然遇到问题，请告诉我，我会重新考虑这个问题。

Answer 3

别再尝试到处使用列表了，这不是 Haskell！别再到处写 fstpair 和 sndpair，这不是 Lisp！

如果您想要 F# 中的简单解决方案，您可以直接这样做，而无需创建任何中间数据结构：

let rec f = function
  | 1L -> 0
  | n when n % 2L = 0L -> 1 + f(n / 2L)
  | n -> 1 + f(3L * n + 1L)

let rec g (li, i) = function
  | 1L -> i
  | n -> g (max (li, i) (f n, n)) (n - 1L)

let euler14 n = g (0, 1L) n

在我的上网本上大约需要 15 秒。如果您想要更省时的结果，请通过数组重用以前的结果：

let rec inside (a : _ array) n =
  if n <= 1L || a.[int n] > 0s then a.[int n] else
    let p =
      if n &&& 1L = 0L then inside a (n >>> 1) else
        let n = 3L*n + 1L
        if n < int64 a.Length then inside a n else outside a n
    a.[int n] <- 1s + p
    1s + p
and outside (a : _ array) n =
  let n = if n &&& 1L = 0L then n >>> 1 else 3L*n + 1L
  1s + if n < int64 a.Length then inside a n else outside a n

let euler14 n =
  let a = Array.create (n+1) 0s
  let a = Array.Parallel.init (n+1) (fun n -> inside a (int64 n))
  let i = Array.findIndex (Array.reduce max a |> (=)) a
  i, a.[i]

在我的上网本上大约需要 0.2 秒。

Answer 4

发现这个寻找 Microsoft.FSharp.Core.Operators.Checked。
我刚刚学习 F#，所以我想参加 Project Euler 14 Challenge。

这使用递归但不使用尾递归。
对我来说大约需要 3.1 秒，但优点是我几乎可以理解它。

let Collatz (n:int64) = if n % 2L = 0L then n / 2L else n * 3L + 1L

let rec CollatzLength (current:int64) (acc:int) =
    match current with 
    | 1L -> acc
    | _ -> CollatzLength (Collatz current) (acc + 1)

let collatzSeq (max:int64) = 
    seq{
        for i in 1L..max do
            yield i, CollatzLength i 0
    }

let collatz = Seq.toList(collatzSeq 1000000L)

let result, steps = List.maxBy snd collatz