方案递归错误

Question

这个递归函数似乎工作正常，将我想要的确切字母 B 和 C 添加到结果列表中，然后当它完成时，它正确地看到已到达最后一个元素。

然后它执行基本情况，并发生一个我无法解释的错误。是什么导致了这个错误？

    (define(preceding-R X Vector result)    
      (if (eq? '() (cdr (vector->list Vector)))
               result
              (helper X Vector result)))

(define (helper X Vector result)
   (if(eqv? X (cadr (vector->list Vector))) ((set! result (cons result (car (vector->list Vector)))) (preceding-R X (list->vector (cdr (vector->list Vector))) result))
                            (preceding-R X (list->vector (cdr (vector->list Vector))) result)))

(preceding-R 'a #(b a c a) '()))

错误：

程序应用：预期程序，给定：#；参数为：((() . b) . c)

Answer 1

这里有一些代码并不是“绝对可怕”：

(define preceding-R 
  (lambda (x vec)
    (define helper
      (lambda (ls)
        (cond
          ((null? ls) '())
          ((null? (cdr ls)) '())
          ((eq? (cadr ls) x) (cons (car ls) (helper (cdr ls))))
          (else (helper (cdr ls))))))
    (helper (vector->list vec))))

> (preceding-R 'a #(b a c a))
(b c)

Eli Barzilay 有一个观点；如果我对原始代码进行评分，我可能会授予不到一半的学分，因为他指出了以下几点：

• 在大多数情况下应该避免 set!，并且通常不允许涉及基本的家庭作业问题方案代码。必须使用 set! 通常表明递归还没有被很好地理解。
• 由于 begin “丢弃”除最后一个表达式之外的所有内容的结果，这意味着非尾部表达式具有副作用（如 set!），因此 begin 通常也不会出现在教育问题中。
• 一遍又一遍地来回转换显然是一种浪费。一次转换就可以了，但是您可能一开始就可以使用列表而不是向量。列表是Scheme 中最常用的数据结构，特别是因为它们与递归配合得很好。
• 您的代码将在第二行的空列表中出错： (preceding-R 'a #()) =>;错误：尝试将 cdr 应用于 '()
• 如果您确实使用 set! 来修改结果，则没有理由传递结果。这是额外的行李。
• Eli 的最后一点是你可以写：

。

(define (helper X Vector result)
  (preceding-R X (list->vector (cdr (vector->list Vector)))
               (if (eq? X (cadr (vector->list Vector)))
                   (cons (car (vector->list Vector)) result)
                   result)))

节省一些重复的代码。

Answer 2

(define (preceding-R X Vector result)    
  (if (eq? '() (cdr (vector->list Vector)))
    result
    (helper X Vector result)))

(define (helper X Vector result)
  (if (eqv? X (cadr (vector->list Vector)))
    (begin
      (set! result (cons (car (vector->list Vector)) result))
      (preceding-R X (list->vector (cdr (vector->list Vector))) result))
    (preceding-R X (list->vector (cdr (vector->list Vector))) result)))

(preceding-R 'a #(b a c a) '())

我添加了开始通话。如果你想要多个表达式，如果你不能将它们包装在 () 中，它会被解释为对 void 的函数调用（由 set 返回！），参数由对前面的 -R 的递归调用返回。