替换 SAS 宏变量中的引号

Question

考虑以下 sas 代码片段：

%macro temp(querystr=);
  filename request temp;

  data _null_;
    file request;

    put "<string>&querystr</string>";
  run;
%mend temp;

%temp(querystr="term 1" and "term2");

请注意，这段代码不会编译，因为当编译器在数据步骤中替换 querystr 时，querystr 中的第一个引号将关闭 put 语句的起始引号。

我想屏蔽查询字符串中的引号，将其转换为有效的 xml 片段，例如：

<string>&quot;term 1&quot; and &quot;term 2&quot;</string>

有没有办法通过正确屏蔽引号将上面的行输出到文件？我尝试将 %sysfunc(TranWrd()) 函数与 %nrbquote() 等屏蔽函数结合使用，但到目前为止我还没有找到可行的解决方案。任何帮助表示赞赏！

Answer 1

将带有 'quot' 选项的 htmlencode 添加到数据步骤，并使用 %bquote 屏蔽引号，直到宏执行。

%macro temp(querystr=);

  filename request temp;

  data _null_;

    file request;

    string = cats('<string>',htmlencode("&querystr",' quot'),'</string>');

    put string;

  run;

%mend temp;

%temp(querystr=%bquote("term 1" and "term2"));

Answer 2

只要双引号平衡，宏就可以正常调用。因此，您不需要强制宏用户宏引用参数。您的宏可以为他们执行此操作，如下所示。

   %macro temp(querystr=);
     filename request temp;
     data _null_;
       file request;
       s = catx(htmlencode("%superq(querystr)","quot"),"<string>","</string>");
       l = length(s);
       put s $varying. l;
     run;
   %mend temp;

   %temp(querystr="term 1" and "term2");

   /* check */
   data _null_;
     infile request;
     input;
     put _infile_;
   run;
   /* on log
   <string>"term 1" and "term2"</string>
   */ 

Answer 3

请尝试以下操作：

options mcompilenote=all;
%macro temp(querystr=); 
  filename request temp; 

  data _null_; 
    file request; 
    querystr=symget('querystr');
    querystr=htmlencode(querystr,'quot');
    *putlog querystr $;
    string="<string>"!!trim(querystr)!!"</string>";
    put string $200.;
    *put "<string>&querystr</string>"; 
  run; 
%mend temp; 

%temp(querystr="term 1" and "term2"); 

Answer 4

只需使用 put 'foo';反而：

%macro temp(querystr=);
  filename request temp;

  data _null_;
    file request;

    put '<string>&querystr</string>';
  run;
%mend temp;

%temp(querystr="term 1" and "term2");