Delphi XE Datasnap 中的传输过滤器

Question

当我尝试为 datasnap 创建自定义传输过滤器并使用它时，当我运行客户端应用程序时，我收到一条错误消息：

模块 ProjectAdminClient.exe 中出现异常 TDBXError。 Filter Log Rejected 设置参数 FilterUnit 给定值 1024。 此时，由于不兼容，服务器通信无法进行。

是什么原因造成的？

Answer 1

您使用过滤器参数吗？我还创建了自定义传输过滤器，但从未遇到过此错误。这是一个不执行任何操作的日志过滤器示例...

unit LogFilter;
interface
uses
  SysUtils, DBXPlatform, DBXTransport;

type
  TLogFilter = class(TTransportFilter)
  public
    constructor Create; override;
    destructor Destroy; override;
    function ProcessInput(const Data: TBytes): TBytes; override;
    function ProcessOutput(const Data: TBytes): TBytes; override;
    function Id: UnicodeString; override;
  end;

const
  LogFilterName = 'Log';

implementation
uses
  CodeSiteLogging;

constructor TLogFilter.Create;
begin
  inherited Create;
  CodeSite.Send(csmBlue,'TLogFilter.Create');
end;

destructor TLogFilter.Destroy;
begin
  CodeSite.Send(csmBlue,'TLogFilter.Destroy');
  inherited Destroy;
end;

function TLogFilter.ProcessInput(const Data: TBytes): TBytes;
begin
  Result := Data;
  CodeSite.Send(csmYellow, 'ProcessInput ' + IntToStr(Length(Data)),
    TEncoding.ASCII.GetString(Data));
end;

function TLogFilter.ProcessOutput(const Data: TBytes): TBytes;
begin
  Result := Data;
  CodeSite.Send(csmOrange, 'ProcessOutput ' + IntToStr(Length(Data)),
    TEncoding.ASCII.GetString(Data));
end;

function TLogFilter.Id: UnicodeString;
begin
  Result := LogFilterName;
end;

initialization
  TTransportFilterFactory.RegisterFilter(LogFilterName, TLogFilter);
finalization
  TTransportFilterFactory.UnregisterFilter(LogFilterName);
end.

这个对我来说效果很好（我即将推出的 Delphi XE DataSnap Development Essentials 课件手册中的示例之一）。

鲍勃·斯沃特·格鲁特耶斯

Answer 2

当我使用 Bob 博士的 Delphi 2010 Datasnap 白皮书中的 LogFilter 遇到类似问题时，我发现了这个问题。

问题（至少部分是）是我在尝试使用日志过滤器的同时加载了 ZLibCompression 过滤器。线索是在 ServerContainerUnit1.dfm 中，

Filters = <
  item
    FilterId = 'ZLibCompression'
    Properties.Strings = (
      'CompressMoreThan=1024')
  end>

我看到 1024 也在错误中，并认为在没有 ZLib 过滤器的情况下值得尝试。我从客户端和服务器中删除了它。现在日志过滤器可以工作了。我获取服务器时间并在 LogFilter 代码中设置断点。