捕获 NullReferenceException 还是先测试 Nothing？

Question

我们有一个属性，其工作是查找描述。如果查找失败，它应该显示一个空字符串。

所以我们可以像这样编写属性：

If foo.bar Is Not Nothing Then
  Return foo.bar.Description
Else
  Return String.Empty
End If

但这涉及执行 foo.bar 两次，如果这样做代价高昂，那么可能更好：

Dim b As bar = foo.bar
If b IsNot Nothing Then
  Return b.Description
Else
  Return String.Empty
End If

但实际上我们想要做的就是将任何类型的错误视为空描述。所以在某些方面这更简单：

Try
  Return foo.bar.Description
Catch e As NullReferenceException
  Return String.Empty
End Try

但是仅仅捕获并忽略错误是否存在任何问题（性能，纯度，其他？）？

您有时会读到抛出异常的成本很高，但我不确定作者的意思是否是使用 Throw 关键字（我没有这样做）构建异常的成本很高，或者他是否意味着允许异常发生的成本很高（就像我会做的那样）。

Answer 1

如果肯定会测试 Nothing 而不是在这里依赖异常。您的代码表明 foo.bar 为 Nothing 的场景是预期场景，而不是例外场景。这样就给出了答案。

抛出异常是一个相对昂贵的操作（从性能角度来看）。无论您是在代码中还是在库代码中抛出它，情况都是如此；这是完全相同的操作。然而，出于性能原因，我不会避免抛出异常，除非我有一个真实的、经过衡量的、关键的业务案例。

在我看来，这主要是一个表达意图的问题；通过测试 Nothing 并优雅地执行操作，您的代码表明了这样一个事实：发生这种情况并不奇怪。

如果您担心执行两次 foo.bar 的性能，首先要做的就是查明情况是否确实如此。如果是这样，可能有一些方法可以解决这个问题（您的代码示例已经包含建议）。

Answer 2

我会采用这种方法：

Dim b As bar = foo.bar
If b IsNot Nothing Then
  Return b.Description
Else
  Return String.Empty
End If

如果以后发现自己经常重复代码的同一部分，您可以将此查找包装到通用函数中，例如：

Private Function GetPropertyOrStringEmptyIfNothing(barObj As bar, propSelector As Func(Of bar, String))
  If barObj IsNot Nothing Then
    Return propSelector(barObj)
  Else
    Return String.Empty
  End If
End Function

这是一个用法示例：

GetPropertyOrStringEmptyIfNothing(foo.bar, Function(x) x.Description)

假设您有一个类似的类，它将起作用在当前范围内声明：

Class bar
  Public Description As String
End Class

就捕获异常的成本而言，这里是我对另一个问题的回答的链接 。它让您了解捕获异常如何影响调试性能以及发布版本的性能。从语义上讲，如果是非异常情况，最好避免抛出异常，正如其他答案中已经提到的那样。

Answer 3

当您期望将其作为受控条件时，您应该始终尝试进行任何测试，仅在可能的情况下使用捕获来处理不需要的错误（我广泛使用不需要的错误，因为某些错误会产生想要的结果）。能够在不捕获异常的情况下处理空字符串，因此请使用它。

在 String 类类型中使用名为 IsNullOrEmpty 或 IsNullOrWhiteSpace 的空字符串测试函数：

    Public Shared Sub Main()

        Dim f As String
        Dim b As String

        Dim emptyResponseString As String = "I was empty"

        'Foo will return a Null String'

        f = foo()

        'Bar will return an instantiated String'

        b = bar()

        If String.IsNullOrEmpty(f) Then
            Console.Out.WriteLine("foo(): " & emptyResponseString)
        Else
            Console.Out.WriteLine("foo(): " & f)
        End If

        If String.IsNullOrEmpty(b) Then
            Console.Out.WriteLine("bar(): " & emptyResponseString)
        Else
            Console.Out.WriteLine("bar(): " & b)
        End If

    End Sub

    Public Shared Function foo() As String
        Return Nothing
    End Function

    Public Shared Function bar() As String
        Return "I am not empty!"
    End Function

这将允许您将异常处理留给意外异常（因为它应该是 ^^ ）

从您的选择来看，第二个最接近我的建议，将您的函数结果放入一个保存变量中，然后使用 String.IsNullOrEmpt 测试该变量，或者如果您想包含空格检查然后 String.IsNullOrWhiteSpace （这也测试空字符串）。

这是运行的代码：

http://ideone.com/CelDe