ActionScript - 使用 JointStyle.MITRE 清除图形 Bug？

Question

在清除/重绘图形时，我遇到了使用 JointStyle.MITER 的不良效果。

我的项目涉及管理具有圆边和锐边的自定义线条图形，这就是为什么我想使用斜接样式。

当线条粗细大大增加时，甚至线条的圆形区域也会受到斜接样式的影响。虽然我觉得这很不幸，但这是可以理解的，而不是我指的错误。当减小线条粗细并不能完全清除图形时，就会出现错误（？），按照代码每次粗细变化时的指示，将线条图形的伪影留在线条曾经所在的位置。工件还留下锋利的边缘，而不仅仅是圆角。

我在 Mac OS X Snow Leopard (10.6.4) 上使用 Flash Player 版本 10.1.53.64。

您可以通过运行下面的示例代码来测试这一点。使用左右键盘箭头更改圆形矩形的描边粗细。

更新：图形伪影是肤浅的。出现后将形状拖动到其位置即可将其删除。代码已更新，具有拖动功能。

package
{
import flash.display.CapsStyle;
import flash.display.JointStyle;
import flash.display.LineScaleMode;
import flash.display.Sprite;
import flash.events.Event;
import flash.events.KeyboardEvent;
import flash.events.MouseEvent;
import flash.ui.Keyboard;

public class StrokeWidth extends Sprite
    {
    private var roundRect:Sprite = new Sprite();
    private var strokeThickness:Number = 6;

    public function StrokeWidth()
        {
        addEventListener(Event.ADDED_TO_STAGE, init);
        }

    private function init(evt:Event):void
        {
        removeEventListener(Event.ADDED_TO_STAGE, init);
        stage.addEventListener(KeyboardEvent.KEY_DOWN, keyDownEventListener);
        roundRect.addEventListener(MouseEvent.MOUSE_DOWN, mouseEventListener);
        roundRect.addEventListener(MouseEvent.MOUSE_UP, mouseEventListener);

        drawRoundRect();
        roundRect.x = roundRect.y = 100;
        addChild(roundRect);
        }

    private function drawRoundRect():void
        {
        roundRect.graphics.clear();
        roundRect.graphics.lineStyle(strokeThickness, 0x000000, 1.0, true, LineScaleMode.NONE, CapsStyle.NONE, JointStyle.MITER);
        roundRect.graphics.beginFill(0xFF0000);
        roundRect.graphics.drawRoundRect(0, 0, 400, 200, 100);
        }

    private function mouseEventListener(evt:MouseEvent):void
        {
        switch  (evt.type)
                {
                case MouseEvent.MOUSE_DOWN: roundRect.startDrag();  break;
                case MouseEvent.MOUSE_UP:   roundRect.stopDrag();   
                }
        }

    private function keyDownEventListener(evt:KeyboardEvent):void
        {
        switch  (evt.keyCode)
                {
                case Keyboard.LEFT:     strokeThickness -= 1;       break;
                case Keyboard.RIGHT:    strokeThickness += 1;
                }

        drawRoundRect();
        }
    }
}

Answer 1

有趣的。该问题是由于 lineStyle 的缩放模式设置为无而引起的：

LineScaleMode.NONE

将其更改为正常可以修复问题：

LineScaleMode.NORMAL

Answer 2

重新创建形状怎么样？