XML-SAX 错误：不是 ARRAY 引用

Question

（使用 WinXP Pro、ActivePerl 5.10.1 和 XML-SAX 0.96）

MyXML.xml 作为此

<?xml version="1.0" standalone="yes"?>
<DocumentElement>
  <subItem>
    <bib>0006</bib>
    <name>Stanley Cheruiyot Teimet</name>
    <team>肯尼亚</team>
    <time>2:17:59</time>
    <rank>1</rank>
    <comment />
    <gender>Male</gender>
    <distance>Full</distance>
    <year>2010</year>
  </subItem>
</DocumentElement>

MyPerl.pl

#!/usr/bin/perl -w
use strict;
use XML::Simple;
use Data::Dumper;
use utf8;

open FILE, ">myXML.txt" or die $!;

my $tree = XMLin('./myXML.xml');
print Dumper($tree);

print FILE "\n";

for (my $i = 0; $i < 1; $i++)
{
    print  FILE "('$tree->{subItem}->[$i]->{distance}')";

}

close FILE;

输出：

D:\learning\perl\im>mar.pl
$VAR1 = {
          'subItem' => {
                         'distance' => 'Full',
                         'time' => '2:17:59',
                         'name' => 'Stanley Cheruiyot Teimet',
                         'bib' => '0006',
                         'comment' => {},
                         'team' => '肯尼亚',
                         'rank' => '1',
                         'year' => '2010',
                         'gender' => 'Male'
                       }
        };
Not an ARRAY reference at D:\learning\perl\im\mar.pl line 41.

我不知道数组引用是什么意思？ Dumper() 运行良好，但无法将数据打印到 TXT 文件。

实际上，示例代码几天前运行得很好，然后我记得我从 V5 升级了我的 Komodo Edit。到最新的V6。

今天，我只是尝试改进脚本，在开始阶段，我修复了另一个错误。在谷歌帮助下“找不到 ParserDetails.ini”。 （我之前没有收到错误！）

但现在我收到 ARRAY 引用错误。我刚才已经通过 PPM 重新安装了 XML-SAX。它仍然不起作用。

Answer 1

您设置的整个 XML 解析堆栈工作正常，如解析树的转储所示。 XML::SAX 不是问题的原因，它只是间接涉及。

该错误只是由于对 XML::Simple 生成的数据结构的访问不当所致。

我能猜到发生了什么。在程序的早期版本中，您启用了 ForceArray 选项（这是一个很好的做法，请参阅 选项 和 STRICT_MODE ，并且编写遍历解析树的算法也考虑到了这一点，即涉及数组访问。

在您的程序的当前版本中，未启用ForceArray，但遍历算法不再与数据结构匹配。我建议重新启用文档中推荐的选项。

#!/usr/bin/env perl
use utf8;
use strict;
use warnings FATAL => 'all';
use IO::File qw();
use XML::Simple qw(:strict);
use autodie qw(:all);

my $xs   = XML::Simple->new(ForceArray => 1, KeyAttr => {}, KeepRoot => 1);
my $tree = $xs->parse_file('./myXML.xml');

{
    open my $out, '>', 'myXML.txt';
    $out->say;
    for my $subitem (@{ $tree->{DocumentElement}->[0]->{subItem} }) {
        $out->say($subitem->{distance}->[0]); # 'Full'
    }
}

这棵树现在看起来像这样：

{
    'DocumentElement' => [
        {
            'subItem' => [
                {
                    'distance' => ['Full'],
                    'time'     => ['2:17:59'],
                    'name'     => ['Stanley Cheruiyot Teimet'],
                    'bib'      => ['0006'],
                    'comment'  => [{}],
                    'team'     => ["\x{80af}\x{5c3c}\x{4e9a}"],
                    'rank'     => ['1'],
                    'year'     => ['2010'],
                    'gender'   => ['Male']
                }
            ]
        }
    ]
}