Perl 如何“使用”？语法工作？

Question

示例代码：

m1.pm

my $a;
my $b;
sub init {
    $a = shift;
    $b = shift;
}

sub printab {
    print "a = -$a-\n";
    print "b = -$b-\n";
}

1;

m2.pm

my $a;
my $b;
sub init {
    $a = shift;
    $b = shift;
}

1;

test.pl

use strict;
use warnings;

use m1;
use m2;

init('hello', 'world');
printab();

运行：

$ perl test.pl
a = --
b = --
$

init('hello', 'world') 调用映射到 m2.pm 并初始化那里的变量（$a 和 $b）。

这是有道理的，但我不明白的是为什么这些值在 test.pl 中不可用。

• 我想在这里做的事情是根本错误的吗？ 使用具有相同命名子例程和变量的两个模块的正确方法是什么？

• Perl use 究竟是如何工作的？如果有人能将它与 C 的 #include 指令进行对比，将会有所帮助。

Answer 1

在 Perl 中，use 关键字与以下内容完全相同：

use Mymodule;

#is the same as

BEGIN {
   require Mymodule;
   Mymodule->import();
}

因此，如果您没有在代码中定义导入例程（或从 Exporter 继承），那么您的模块没有将任何内容导入 test.pl

正如 Sinan 所发现的那样，您没有在模块中声明包，因此它们默认为 main 包。在这种情况下，所有子例程都位于 main 中，但词法变量（用 my 声明）的作用域仅限于声明它们的文件。

因此 m1 定义了词法 $a 和 $b 所在的 sub init 和 sub printab范围。但是，当 test.pl 加载 m2 时，init 例程将被新定义覆盖，新定义不再围绕两个词法封闭。因此它正在写入包变量 $main::a 和 $main::b 而不是 printab 绑定到的词法。

如果您启用了警告（学习时总是应该这样做），您将会收到有关子例程重新定义的警告。

您应该以： 开始每个模块

package Some::Package::Name;
use warnings;
use strict;

，然后以： 结束每个模块，

1;

这是因为当您use/require 一个模块时，它需要在最后返回一个 true 值，以便 Perl 知道它已加载适当地。

Answer 2

首先，请阅读 perldoc perlmod。

您没有在这两个模块中声明命名空间，因此所有内容都位于 main 命名空间中。在 m1.pm 中声明 package m1;，在 m2.pm 中声明 package m2;。

至少，您应该实现一个 import 方法（或继承 Exporter 提供的方法），以便使用模块的程序可以决定从哪里导入什么。

在我看来，您似乎正在探索面向对象的边缘。

此外：

• 避免使用 $a 和 $b 作为变量名，因为很容易将它们与包变量 $a 和$b 由 sort 使用。

• 不要使用小写模块名称：它们是为 pragmata 保留的。

一个最小的实现（为了测试方便，全部在一个文件中）如下所示：

package My::M1;

use strict; use warnings;

sub new { my $class = shift; bless { @_ } => $class }

sub a {
    my $self = shift;
    my ($v) = @_;
    $self->{a} = $v if @_;
    return $self->{a};
}

sub b {
    my $self = shift;
    my ($v) = @_;
    $self->{b} = $v if @_;
    return $self->{b};
}

package My::M2;

use strict; use warnings;
use base 'My::M1';

sub printtab {
    my $self = shift;
    for my $x (qw(a b)) {
        printf "%s = -%s-\n", $x, $self->$x;
    }
}

package main;

my $m = My::M2->new(a => 'hello', 'b' => 'world');
$m->printtab;

Answer 3

printab() 在文件 m1.pm 中定义，并且只能访问 $a 和 $b作用域为该文件的变量。 m2.pm 中的变量 $a 和 $b 的作用域为该文件，并且它们是不同的变量比 m1.pm 中的 $a 和 $b 更重要。

init() 设置范围在 m2.pm 中的变量（因为这是定义 &init 函数的最后一个位置），所以它不是设置 printab() 将尝试打印的相同变量。