在 Clojure 中添加向量的惯用方法是什么？

Question

添加到列表很容易：

user=> (conj '(:bar :baz) :foo)
(:foo :bar :baz)

附加到向量很容易：

user=> (conj [:bar :baz] :foo) 
[:bar :baz :foo]

如何（惯用地）添加到向量，同时返回向量？ 这不起作用，因为它返回一个 seq，而不是一个向量：

user=> (cons :foo [:bar :baz])     
(:foo :bar :baz)

这很丑陋（IMVHO）：

user=> (apply vector (cons :foo [:bar :baz])) 
[:foo :bar :baz]

注意：我基本上只想要一个可以附加和前置的数据结构。附加到大型列表应该会产生很大的性能损失，所以我想到了向量。

Answer 1

向量不是为前置而设计的。您只有 O(n) 前置：

user=> (into [:foo] [:bar :baz])
[:foo :bar :baz]

您想要的很可能是 手指树。

Answer 2

我知道这个问题很老了，但没有人说过任何关于差异的事情
列表，既然你说你真的只是想要一些可以附加的东西
并加上前缀，听起来差异列表可能对您有帮助。
它们在 Clojure 中似乎并不流行，但它们非常简单
实现起来比手指树复杂得多，所以我做了一个
微小的差异列表库，刚才（甚至测试了它）。这些
在 O(1) 时间内连接（前置或附加）。转换差值
列表回到列表应该花费你 O(n)，这是一个很好的权衡，如果
你做了很多串联。如果你没有做很多事情
连接，然后就坚持列表，对吧？ :)

以下是这个小库中的函数：

dl: 差异列表实际上是一个连接其自身的函数
包含参数的内容并返回结果列表。每次
你产生了一个差异列表，你正在创建一个小函数
就像数据结构一样。

dlempty：由于差异列表只是将其内容连接到
参数，空的差异列表与恒等式是一样的
功能。

undl：由于差异列表的作用，您可以将
只需用 nil 调用它即可将列表与普通列表区别，所以这
功能并不是真正需要的；这只是为了方便。

dlcons： 将一个项目放在列表的前面——不完全是
必要的，但 consing 是一个足够常见的操作，它只是一个
一行（就像这里的所有函数一样）。

dlappend：连接两个差异列表。我认为它的定义是
最有趣的——来看看！ :)

现在，这是那个小库 —— 5 个单行函数，可为您提供 O(1)
附加/前置数据结构。不错吧？啊，拉姆达的美丽
微积分...

(defn dl
  "Return a difference list for a list"
  [l]
  (fn [x] (concat l x)))

; Return an empty difference list
(def dlempty identity)

(defn undl
  "Return a list for a difference list (just call the difference list with nil)"
  [aDl]
  (aDl nil))

(defn dlcons
  "Cons an item onto a difference list"
  [item aDl]
  (fn [x] (cons item (aDl x))))

(defn dlappend
  "Append two difference lists"
  [dl1 dl2]
  (fn [x] (dl1 (dl2 x))))

您可以通过以下方式查看它的实际效果：

(undl (dlappend (dl '(1 2 3)) (dl '(4 5 6))))

返回：

(1 2 3 4 5 6)

这也返回相同的内容：

((dl '(1 2 3)) '(4 5 6))

享受差异列表的乐趣！

更新

以下是一些可能更难理解但我认为更好的定义：

(defn dl [& elements] (fn [x] (concat elements x)))
(defn dl-un [l] (l nil))
(defn dl-concat [& lists] (fn [x] ((apply comp lists) x)))

这可以让你说这样的话：

(dl-un (dl-concat (dl 1) (dl 2 3) (dl) (dl 4)))

which will return

(1 2 3 4)

Answer 3

如果您不担心准引用，那么这个解决方案实际上非常优雅（对于“优雅”的某些定义）：

> `[~:foo ~@[:bar :baz]]

[:foo :bar :baz]

我实际上在实际代码中偶尔使用它，因为声明性语法使其非常具有可读性（恕我直言）。

Answer 4

正如用户 optevo 在手指树答案下的评论中所说，您可以使用 clojure/core。 rrb-vector lib，它实现了RRB树：

RRB-Trees 基于 Clojure 的 PersistentVectors 构建，添加了对数时间串联和切片。除了缺少 vector-of 函数之外，ClojureScript 支持相同的 API。

我决定将其作为单独的答案发布，因为我认为这个图书馆值得这样做。它支持 ClojureScript，并由 Michał Marczyk 维护，他在 Clojure 社区中因其致力于实现各种数据结构。

Answer 5

我建议使用便利功能 内置于图珀洛图书馆。例如：

(append [1 2] 3  )   ;=> [1 2 3  ]
(append [1 2] 3 4)   ;=> [1 2 3 4]

(prepend   3 [2 1])  ;=> [  3 2 1]
(prepend 4 3 [2 1])  ;=> [4 3 2 1]

相比之下，使用原始 Clojure 很容易犯错误：

; Add to the end
(concat [1 2] 3)    ;=> IllegalArgumentException
(cons   [1 2] 3)    ;=> IllegalArgumentException
(conj   [1 2] 3)    ;=> [1 2 3]
(conj   [1 2] 3 4)  ;=> [1 2 3 4]

; Add to the beginning
(conj     1 [2 3] ) ;=> ClassCastException
(concat   1 [2 3] ) ;=> IllegalArgumentException
(cons     1 [2 3] ) ;=> (1 2 3)
(cons   1 2 [3 4] ) ;=> ArityException