Delphi中枚举可能的设定值

Question

我在 Delphi 中有一个计算算法，有许多不同的选项，我需要尝试每种选项的组合来找到最佳解决方案。

TMyOption = (option1, option2, option3, option4);
TMyOptions = set of TMyOption;

我想知道是否使用整数循环来枚举它们：

for EnumerationInteger := 0 to 15 do begin
    Options := TMyOptions(EnumerationInteger);
end;

这无法编译。我想知道是否有任何相当简单的方法可以从 Integer 转换为 Set（网上的大多数问题都尝试采用另一种方式，从 Set 转换为 Integer），如果有的话，它是什么？

另一种可能性是只使用整数作为位字段：

C_Option1 = 1;
C_Option2 = 2;
C_Option3 = 4;
C_Option4 = 8;

然后用按位和测试成员资格：

if (Options and C_Option2) > 0 then begin
    ...
end;

我已经尝试过这个，它有效，但感觉使用集合会更自然并且更好地使用类型系统（即使我要超出上述类型系统来枚举集合）。

有没有比枚举底层整数表示更好/更安全的方法来枚举所有可能的集合组合？

注意：

1. 我知道理论上不能保证集合的整数值（尽管我怀疑如果您不使用枚举编号，它们在实践中就会得到保证）。
2. 可能有四个以上的选项（是的，我知道它呈指数级增长，如果选项太多，算法可能会永远持续下去）。

Answer 1

我知道这个问题很老了，但这是我的偏好，因为它对我来说简单而自然：

function NumericToMyOptions(n: integer): TMyOptions;
var
  Op: TMyOption;
begin
  Result:= [];
  for Op:= Low(TMyOption) to High(TMyOption) do
    if n and (1 shl ord(Op)) > 0 then Include(Result, Op);
end;

Answer 2

尝试

var EnumerationByte: Byte;
...
for EnumerationByte := 0 to 15 do begin
    Options := TMyOptions(EnumerationByte);
end;

Answer 3

您的代码无法编译，因为您的枚举 (TMyOption) 的值少于 8 个，并且 Delphi 使用集合的最小可能大小（以字节为单位）。因此，字节变量将适合您。

如果您的集合包含超过 8 个但少于 16 个可能的元素，则可以使用 Word（而不是整数）。

对于大于 16 但小于 32 的 DWord 变量和类型转换。

对于超过 32 个可能的元素，我认为更好的方法是使用字节数组或类似的东西。

Answer 4

500 - 内部服务器错误的答案可能是最简单的。

另一种不太可能因选项数量的变化而中断的方法是声明一个布尔数组，并打开/关闭它们。但这比使用纯整数要慢。主要优点是，您无需更改所使用的整数类型，并且如果您有超过 32 个选项，则可以使用它。

procedure DoSomething
var BoolFlags : Array[TOption] of Boolean;
    I: TOption;
  function GetNextFlagSet(var Bools : Array of Boolean) : Boolean;
  var idx, I : Integer;
  begin
    idx := 0;
    while Bools[idx] and (idx <= High(Bools)) do Inc(idx);

    Result := idx <= High(Bools);

    if Result then
      for I := 0 to idx do
        Bools[I] := not Bools[I];
  end;
begin
  for I := Low(BoolFlags) to High(BoolFlags) do BoolFlags[i] := False;

  repeat
    if BoolFlags[Option1] then
      [...]

  until not GetNextFlagSet(BoolFlags);
end;

Answer 5

从 Integer 转换为 Set 是不可能的，但是 Tondrej 曾经写过 关于 SetToString 和 StringToSet 的博客文章，其中公开了您的内容希望在 SetOrdValue 方法中：

uses
  TypInfo;

procedure SetOrdValue(Info: PTypeInfo; var SetParam; Value: Integer);
begin
  case GetTypeData(Info)^.OrdType of
    otSByte, otUByte:
      Byte(SetParam) := Value;
    otSWord, otUWord:
      Word(SetParam) := Value;
    otSLong, otULong:
      Integer(SetParam) := Value;
  end;
end;

您的代码将变成这样：

for EnumerationInteger := 0 to 15 do begin
    SetOrdValue(TypeInfo(TMyOptions), Options, EnumerationInteger);
end;

--jeroen

Answer 6

问题是您试图转换为集合类型而不是枚举类型。您可以在整数和枚举之间进行转换，因为两者都是序数类型，但不能转换为集合，因为它们使用您已经注意到的位字段。如果你使用：

for EnumerationInteger := 0 to 15 do begin
  Option := TMyOption(EnumerationInteger);
end;

它会起作用，尽管不是你想要的。

几个月前我遇到了同样的问题，并得出结论，你不能在 Delphi 中枚举集合的内容（至少在 Delphi 7 中），因为该语言没有在集合上定义此类操作。

编辑：看来你甚至可以在D7中看到对此答案的评论。