.Net 常量的 F# 模式匹配

Question

下一个示例中的代码

open System.Drawing

let testColor c =
    match c with
    | Color.Black -> 1
    | Color.White -> 0
    | _ -> failwith "unexpected color"

无法编译。错误为错误 1 ​​未定义字段、构造函数或成员“Black”。

如何针对以大写字母开头的 .Net 常量或枚举进行模式匹配？

就其价值而言，编译器是“Microsoft (R) F# 2.0 Interactive build 4.0.30319.1”。

Answer 1

扩展 Brian 的答案，模式匹配与 switch 语句是不同的野兽。它们测试并分解输入的结构，而不是测试对象的相等性。但是，如果在整个程序中经常使用将颜色划分为黑色、白色和其他颜色，则活动模式可能是一个选择。对于一次性“样板”成本，它们可以让您围绕正在操作的对象定义一种结构。例如，

open System.Drawing
let (|Black|White|Other|) (color:Color) =
    if color = Color.Black then Black
    elif color = Color.White then White
    else Other

let testColor c =
    match c with
    | Black -> 1
    | White -> 0
    | Other -> failwith "unexpected color"

或者，如果您同样只处理黑色和白色，但您总是希望黑色计算为 1，白色计算为 0，那么您可以使用部分活动模式：

let (|KnownColor|_|) (color:Color) =
    if color = Color.Black then Some(1)
    elif color = Color.White then Some(0)
    else None

let testColor2 c =
    match c with
    | KnownColor i -> i
    | _ -> failwith "unexpected color"

更一般地，您甚至可以模拟 switch 语句使用通用的部分活动模式：

let (|Equals|_|) (lhs) (rhs)  =
    if lhs = rhs then Some(lhs) else None

let testColor3 c =
    match c with
    | Equals Color.Black _ -> 1
    | Equals Color.White _ -> 0
    | _ -> failwith "unexpected color"

let testString c =
    match c with
    | Equals "Hi" _ -> 1
    | Equals "Bye" _ -> 0
    | _ -> failwith "unexpected string"

Answer 2

您不能对任意对象值进行模式匹配。使用 if then else 或 when 条件：

let testColor c = 
    match c with 
    | c when c = Color.Black -> 1 
    | c when c = Color.White -> 0 
    | _ -> failwith "unexpected color"