有没有办法在 REXX 中进行关联数组？

Question

我有一些 Perl 代码（用于性能分析）首先在 Linux 下开发，现在需要移植到大型机。显然 REXX 是该平台上选择的脚本语言，但这个 Perl 脚本严重依赖关联数组（基本上是索引为字符串的数组）。

REXX中有这样的方法吗？我将如何编写类似以下内容的代码：

$arr{"Pax"} = "Diablo";
$arr{"Bob"} = "Dylan";
print $arr{"Pax"} . "\n";
if (defined $arr{"no"}) {
        print "Yes\n";
} else {
        print "No\n";
}

Answer 1

你可以使用主干变量，不完全像数组，但非常相似

/* REXX */
NAME = PAX
ARRAY.NAME = "DIABLO"
NAME = BOB
ARRAY.NAME = "DYLAN"
NAME = 'PAX'
SAY "ARRAY.PAX " IS ARRAY.NAME
NAME = 'BOB'
SAY "ARRAY.BOB " IS ARRAY.NAME
NAME = 'SANDY'
SAY "ARRAY.SANDY " IS ARRAY.NAME
IF ARRAY.NAME = "ARRAY.SANDY" THEN SAY "ARRAY.SANDY IS EMPTY"

上面的Rexx将打印

ARRAY.PAX  IS DIABLO
ARRAY.BOB  IS DYLAN
ARRAY.SANDY  IS ARRAY.SANDY
ARRAY.SANDY IS EMPTY

它们也可以像abc一样复合
如果为空，stem 变量将返回其自身。
据我所知，没有办法迭代不使用连续数字作为索引的词干。

参考 Stem 变量的 IBM 手册

Perl 作为额外的免费功能提供给ZOS IBM z/OS 移植工具

Answer 2

我只是想对 Deuian 给出的答案补充一点。
我同意，REXX 干变量
就是答案。

简单的 REXX 变量默认为其自己的名称。例如：

/* REXX */
SAY X

将打印“X”，直到为 X 分配其他值：

/* REXX */
X = 'A'
SAY X

将打印“A”。

到目前为止还没有什么大的惊喜。干变量有点不同。这
词干的头部永远不会被评估，只会评估初始点之后的位
是。

举例说明：

/* REXX */                                                           
X. = 'empty'   /* all unassigned stem values take on this value */
A. = 'nil'
B = 'A'        /* simple variable B is assigned value A */                                                      
X = 'A'        /* simple variable X is assigned value A */                                                      
SAY X.A        /* prints: empty */                                 
X.A = 'hello'  /* Stem X. associates value of A with 'hello' */
SAY X.A        /* prints: hello */                                   
SAY X.B        /* prints: hello */                                   
SAY X.X        /* prints: hello */                                   

请注意，X 和 A 词干名称未计算，但是，
它们后面出现的 X 和 A 变量是。有些人认为这是一个
有点令人困惑——想一想就会发现
很有道理。

REXX 的 Z/OS 版本没有提供自然的迭代方式
一个主干变量。最简单的方法是建立自己的索引。
例如：

/* REXX */
X. = ''
DO I = 1 TO 10
  J = RANDOM(100, 500) /* Random # 100..500 */
  X.INDEX = X.INDEX J  /* concatinate J's with 1 space between */
  X.J = 'was picked'   /* Associate 'was picked' with whatever J evalauates to */
  END

DO I = 1 TO WORDS(X.INDEX) /* Number of blank delimited 'words' */
  J = WORD(X.INDEX, I)     /* Extract 1 'word' at a time */
  SAY J X.J                /* Print 'word' and its associated value */
  END

非常简单，但说明了这个想法。只要确保 INDEX （或您的任何名称）
选择）来保存索引名称永远不会作为关联值弹出！如果可能的话，请使用其他变量来保存索引。

最后一点。请注意，我的每个示例都以 /* REXX */ 开头，您可能会发现
这需要成为 Z/OS 下 REXX 程序的第一行。