Maple 13：如何将 true 变为 1，将 false 变为 0？

Question

一般来说，我需要的是类型转换指令，例如能够在 true 上相乘，如 5 * true 和 get5 或 x * false并得到0。

这样的事该怎么办呢？

Answer 1

有多种方法可以实现这种效果，您选择哪种方法可能取决于您打算用它做什么的更多细节。

最简单的是使用 2 参数 eval（或 subs，因为评估应该是由于涉及精确 1 或 0 的乘积的自动简化而发生）。

> eval( 5*true, [true=1,false=0]);
                           5
> eval( x*false, [true=1,false=0]);
                           0

当然，您可以创建一个过程来处理该评估，

> T := expr -> eval(expr,[true=1,false=0]):

> T( 5*true );
                           5
> T( x*false );
                           0

您还可以尝试使用模块来导出（从而在交互使用的“顶层”重新定义）增强的 *。

注意。下面这个导出过程 * 的更仔细的版本只会在作为整个被乘数出现时替换“true”和“false”，而不是在整个表达式中进行替换。 （标量表达式中可以包含未计算的函数调用，例如可选参数中会出现“true”和“false”。理想情况下，应将它们单独保留。）

> M:=module() option package; export `*`;
>  `*`:=proc(ee::seq(anything))
>         :-`*`(op(eval([ee],[true=1,false=0])));
>       end proc;
> end module:

> with(M):

> 5*true;
                           5
> x*false;
                           0

> a*b*c;
                         a b c

> eval( %, b=false ); # this doesn't play along
                       a false c

请注意最后一个结果中的“false”替换是如何发生的不会产生 0。这是因为 a*b*c（对于未知的 a、b 和 c）的结果是全局 :-* 而不是新的 *。因此，当 b=false 被替换时，不会调用新的 *。也可以解决这个问题，尽管结果显示不太好（并且解决方法可能会“破坏”您可能想要实现的其他东西），

> M:=module() option package; export `*`;
>   `*`:=proc(ee::seq(anything))
>          local res;
>          res:=:-`*`(op(eval([ee],[true=1,false=0])));
>          if type(res,:-`*`) then
>            'procname'(op(res));
>          else
>            res;
>          end if;
>        end proc;
> end module:

> with(M):

> 5*true;
                           5
> x*false;
                           0

> a*b*c;
                     `*`(`*`(a, b), c)

> eval( %, b=false );
                           0

在上面的最后一个示例中，对象看起来像 < code>*(*(a, b), c) 实际上是对新 * 的未计算函数调用。因此，当 b=false 被替换时，就会调用新的 * 并且可以获得所需的结果。 （希望这不会导致我忽略的情况下的无限递归。）

Answer 2

你可以这样做：

subs([false=0, true=1], expr);