VB.Net - “与”和闭包不能混用

Question

只是想我会分享这个以防其他人遇到这个问题。
我今天做了类似的事情，我花了一段时间才弄清楚为什么这会在运行时导致问题。

此代码：

Public Class foo
  Public bar As String = "blah"
End Class

Public Sub DoInline()
  Dim o As New foo
  Dim f As Func(Of String)
  With o
    f = Function() .bar
  End With
  Try
    Console.WriteLine(f.DynamicInvoke())
  Catch ex As Reflection.TargetInvocationException
    Console.WriteLine(ex.InnerException.ToString)
  End Try
End Sub

抛出 NullReferenceException。似乎 With 正在使用闭包作为其临时存储，并且在“End With”处，它将闭包的变量设置为 Nothing。

这是 RedGate Reflector 中的代码：

Public Shared Sub DoInline()
    Dim o As New foo
    Dim $VB$Closure_ClosureVariable_7A_6 As New _Closure$__1
    $VB$Closure_ClosureVariable_7A_6.$VB$Local_VB$t_ref$L0 = o
    Dim f As Func(Of String) = New Func(Of String)(AddressOf $VB$Closure_ClosureVariable_7A_6._Lambda$__1)
    $VB$Closure_ClosureVariable_7A_6.$VB$Local_VB$t_ref$L0 = Nothing 
    Try 
        Console.WriteLine(RuntimeHelpers.GetObjectValue(f.DynamicInvoke(New Object(0  - 1) {})))
    Catch exception1 As TargetInvocationException
        ProjectData.SetProjectError(exception1)
        Console.WriteLine(exception1.InnerException.ToString)
        ProjectData.ClearProjectError
    End Try
End Sub

请注意，

$VB$Closure_ClosureVariable_7A_6.$VB$Local_VB$t_ref$L0 = Nothing 

我真正能问的唯一“问题”是；这是一个错误还是一个奇怪的设计决策，由于某种原因我没有看到。 从现在开始我几乎会避免使用“With”。

Answer 1

此行为是“设计使然”，是由于 With 语句的一个经常被误解的细节造成的。

With 语句实际上将表达式作为参数而不是直接引用（即使它是最常见的用例之一）。语言规范第 10.3 节保证传递到 With 块的表达式仅计算一次，并且可用于执行 With 语句。

这是通过使用临时来实现的。因此，当在 With 语句中执行 .Member 表达式时，您访问的不是原始值，而是指向原始值的临时值。它允许其他有趣的场景，如下所示。

Dim o as New Foo
o.bar = "some value"
With o   
  o = Nothing
  Console.WriteLine(.bar) ' Prints "some value"
End With

这是可行的，因为在 With 语句中，您不是对 o 进行操作，而是对指向原始表达式的临时指针进行操作。仅保证此临时变量在 With 语句的生命周期内保持活动状态，因此最终不会 Nothing 被删除。

在您的示例中，闭包正确捕获了临时值。因此，当 With 语句完成后执行它时，临时是 Nothing 并且代码相应地失败。

Answer 2

我实际上只看到一个错误，编译器应该为此生成一个错误。实施起来应该不难。您可以在 connect.microsoft.com 上报告该问题