将 python-mode 与 emacs 的 org-mode 结合起来

Question

我将 org-mode 与 lisp-mode 结合起来，在 emacs 中为 lisp 代码实现了漂亮的代码折叠： lisp-orgi-mode。 基本上，我使用“;”而不是 '*' 作为标题字符。对于注释，我只是在“;”之前加了一个空格，使其成为“;”所以它不算是标题...

但是，用 python-mode 做同样的事情不起作用...可能是因为 python 注释使用的“#”字符干扰了 org-mode 设置...

任何人能够成功地组合功能吗？ 我知道人们将 python 模式与大纲模式结合起来（链接)，但 ouline-mode 不如 org-mode...

编辑：让它与 outline-magic: python-magic.el

Answer 1

我使用 hideshow-org (以及这里的一个小介绍）就是为了这个目的，我认为它真的非常非常好。

这些是一些额外但有用的片段：

(dolist (hook (list 'c-mode-common-hook
            'emacs-lisp-mode-hook
            'java-mode-hook
            'lisp-mode-hook
            'perl-mode-hook
            'sh-mode-hook))
  (add-hook hook 'my-hideshow-hook))

(defun my-hideshow-hook ()
  "thisandthat."
  (interactive)
  (progn (require 'hideshow-org)
     (global-set-key (kbd "C-c h") 'hs-org/minor-mode)
     (hs-org/minor-mode)))

(defadvice goto-line (after expand-after-goto-line activate compile)
  "hideshow-expand affected block when using goto-line in a collapsed buffer"
  (save-excursion
    (hs-show-block)))

Answer 2

好吧，我的大纲次要模式与以下大纲正则表达式配合得很好： "[ \t]*# \|[ \t]+\(class\|def\|if\|elif\|else\|while \|对于\|尝试\|除了\|与\) "
现在我使用 python 语法和注释行作为标题进行代码折叠。
是否可以调整您的代码以使用 tab 调用“indent-for-tab-command”，如果没有什么可做的，则调用“outline-cycle”？

python-magic.el：

; require outline-magic.el by CarstenDominik found here: 
; http://www.astro.uva.nl/~dominik/Tools/outline-magic.el
; modified code here by Nikwin slightly found here: 
;  http://stackoverflow.com/questions/1085170/how-to-achieve-code-folding-effects-in-emacs/1085551#1085551

(add-hook 'outline-minor-mode-hook 
           (lambda () 
             (require 'outline-magic)
))
(add-hook 'python-mode-hook 'my-python-outline-hook)

(defun py-outline-level ()
  (let (buffer-invisibility-spec)
    (save-excursion
      (skip-chars-forward "    ")
      (current-column))))

(defun my-python-outline-hook ()
  (setq outline-regexp "[ \t]*# \\|[ \t]+\\(class\\|def\\|if\\|elif\\|else\\|while\\|for\\|try\\|except\\|with\\) ")
  (setq outline-level 'py-outline-level)

  (outline-minor-mode t)
  (hide-body)
  (show-paren-mode 1)
  (define-key python-mode-map [tab] 'outline-cycle)
  (define-key outline-minor-mode-map [S-tab] 'indent-for-tab-command)
  (define-key outline-minor-mode-map [M-down] 'outline-move-subtree-down)
  (define-key outline-minor-mode-map [M-up] 'outline-move-subtree-up)
)
(provide 'python-magic)

Answer 3

我认为 outline-magic 已被 outshine 取代，我不知道上面的代码是否适用于它。但我能够让以下代码正常工作，由 Ryan Davis 的博文：

(defun python-mode-outline-hook ()
  (setq outline-level 'python-outline-level)

  (setq outline-regexp
    (rx (or
         ;; Commented outline heading
         (group
          (* space)  ; 0 or more spaces
          (one-or-more (syntax comment-start))
          (one-or-more space)
          ;; Heading level
          (group (repeat 1 8 "\*"))  ; Outline stars
          (one-or-more space))

         ;; Python keyword heading
         (group
          ;; Heading level
          (group (* space)) ; 0 or more spaces
          bow
          ;; Keywords
          (or "class" "def" "else" "elif" "except" "for" "if" "try" "while")
          eow)))))

(defun python-outline-level ()
  (or
   ;; Commented outline heading
   (and (string-match (rx
               (* space)
               (one-or-more (syntax comment-start))
               (one-or-more space)
               (group (one-or-more "\*"))
               (one-or-more space))
              (match-string 0))
    (- (match-end 0) (match-beginning 0)))

   ;; Python keyword heading, set by number of indentions
   ;; Add 8 (the highest standard outline level) to every Python keyword heading
   (+ 8 (- (match-end 0) (match-beginning 0)))))

(add-hook 'python-mode-hook 'python-mode-outline-hook)

也许有人会发现这很有用。我认为这是一种使代码编辑和导航变得更容易的奇妙方法。