使用 LINQ to SQL 时，我可以将本地数据的值与数据库返回的值混合吗？

Question

我正在使用 LINQ 创建一个 xml 文件，如下所示...

   Public Sub CreateXml()
        Dim db As New MDataContext
        Dim Customers = <gallery columns="3" rows="3">
                            <%= From customer In db.Customers _
                                Select <customer>
                                           <name><%= customer.CustName %></name>
                                           <surname><%= customer.Surname %></surname>
                                       </customer> %>
                        </gallery>
        Customers.Save("d:\1.xml")
    End Sub

我可以将本地值与从 LINQ 查询返回的值混合在一起吗... 像下面这样的东西吗？

 Public Sub CreateXml(ByVal **Col** As String, ByVal **Row** As String)
        Dim db As New MDataContext
        Dim Customers = <gallery columns="& **Col** &" rows="& **Row** &">
                            <%= From customer In db.Customers _
                                Select <customer>
                                           <name><%= customer.CustName %></name>
                                           <surname><%= customer.Surname %></surname>
                                       </customer> %>
                        </gallery>

        Customers.Save("d:\1.xml")
        Process.Start("d:\1.xml")
    End Sub

Answer 1

您应该能够嵌入这两个变量的值，就像处理 customer.CustName 和 customer.Surname 一样，例如

Public Sub CreateXml(ByVal cols As Integer, ByVal rows As Integer)
    Dim db As New MDataContext
    Dim Customers = <gallery columns="<%= cols %>" rows="<%= rows %>">
                        <%= From customer In db.Customers _
                            Select <customer>
                                       <name><%= customer.CustName %></name>
                                       <surname><%= customer.Surname %></surname>
                                   </customer> %>
                    </gallery>

    Customers.Save("d:\1.xml")
    Process.Start("d:\1.xml")
End Sub

严格来说，您应该进行适当的 ToString() 调用，例如<%= cols.ToString(CultureInfo.InvariantCulture) %>。通过这种方式，您可以确保更改不会引入任何不必要的装箱，并且也独立于执行线程的区域性，尽管后者不太可能对 Integer 变量产生任何影响。